loop through all cells in all sheets in workbook, change format if red

Question

I'm trying to change all red text to black in all cells for all sheets of an excel workbook. I'm using the following:

Sub RedToBlack()
Dim Current As Worksheet
For Each Current In Worksheets
For Each cell In Current
    If cell.Font.ColorIndex = 3 Then
        cell.Font.ColorIndex = 0
    End If
  Next
Next
End Sub

I know this is wrong, but wanted to give a sense of what I'm trying to do. Can anyone offer advice? Thanks for your help, I'm very new to this.

Answer 1

What you have would probably do the job. However, it would be extremely inefficient. A better way would be to use a find and replace like this.

'set the next find to find the red
With Application.FindFormat.Font
     .ColorIndex = 3
End With
'set the next find to replace with black
With Application.ReplaceFormat.Font
     .ColorIndex = 1
End With

'Do the actual replacing
For Each aSheet In ActiveWorkbook.Worksheets
     aSheet.Activate

     Cells.Replace What:="", Replacement:="", LookAt:=xlPart, SearchOrder:= _
     xlByRows, MatchCase:=False, SearchFormat:=True, ReplaceFormat:=True
Next aSheet

This does it for all the cells in all the sheets for the whole workbook. You can also do this by going to the normal finding and replace window then pressing the options button.

Answer 2

Sub change_color()
For Each sht In ActiveWorkbook.Sheets
    Set rng = sht.UsedRange
        For Each cell In rng
            If cell.Font.ColorIndex = 3 Then
                cell.Font.ColorIndex = 0
            End If
        Next cell
Next sht
End Sub