Perl的`（？PARNO）`在完成时会丢弃它自己的命名捕获吗？

Question

递归正则表达式是否理解命名捕获？ 在(?{{ code }})的文档中有一个注释，它是一个独立的子模式，有自己的一组捕获，在子模式完成时被丢弃，并且(?PARNO)中有一个注释，它“类似于(?{{ code }}) 。 (?PARNO)丢弃自己的命名捕获？

我正在写关于Perl的Mastering Perl的递归正则表达式。 perlre已经有一个平衡parens的例子（我在Perl正则表达式中匹配平衡括号中显示它），所以我想我会尝试平衡引号：

#!/usr/bin/perl
# quotes-nested.pl

use v5.10;

$_ =<<'HERE';
He said 'Amelia said "I am a camel"'
HERE

say "Matched!" if m/
    (
        ['"]
            ( 
                (?: 
                    [^'"]+
                    | 
                    ( (?1) ) 
                )* 
            )
        ['"]
    )
    /xg;

print "
1 => $1
2 => $2
3 => $3
4 => $4
5 => $5
";

这有效，两个报价显示在$1 $3和$3 ：

Matched!
1 => 'Amelia said "I am a camel"'
2 => Amelia said "I am a camel"
3 => "I am a camel"
4 => 
5 => 

没关系。 我明白那个。 但是，我不想知道这些数字。 所以，我让第一个捕获组成为命名捕获并查看%-期望看到我之前在$1和$2看到的两个子串：

use v5.10;

$_ =<<'HERE';
He said 'Amelia said "I am a camel"'
HERE

say "Matched [$+{said}]!" if m/
    (?<said>
        ['"]
            ( 
                (?: 
                    [^'"]+
                    | 
                    (?1) 
                )* 
            )
        ['"]
    )
    /xg;

use Data::Dumper;
print Dumper( \%- );

我只看到第一个：

Matched ['Amelia said "I am a camel"']!
$VAR1 = {
          'said' => [
                      '\'Amelia said "I am a camel"\''
                    ]
        };

我预计(?1)将重复第一个捕获组中的一切，包括一个名为捕捉said 。 我可以通过命名一个新的捕获来解决这个问题：

use v5.10;

$_ =<<'HERE';
He said 'Amelia said "I am a camel"'
HERE

say "Matched [$+{said}]!" if m/
    (?<said>
        ['"]
            ( 
                (?: 
                    [^'"]+
                    | 
                    (?<said> (?1) ) 
                )* 
            )
        ['"]
    )
    /xg;

use Data::Dumper;
print Dumper( \%- );

现在我得到了我的期望：

Matched ['Amelia said "I am a camel"']!
$VAR1 = {
          'said' => [
                      '\'Amelia said "I am a camel"\'',
                      '"I am a camel"'
                    ]
        };

我认为我可以通过将命名捕获移动到一个级别来解决这个问题：

use v5.10;

$_ =<<'HERE';
He said 'Amelia said "I am a camel"'
HERE

say "Matched [$+{said}]!" if m/
    (
        (?<said>
        ['"]
            ( 
                (?: 
                    [^'"]+
                    | 
                    (?1)
                )* 
            )
        ['"]
        )
    )
    /xg;

use Data::Dumper;
print Dumper( \%- );

但是，这并不赶上小串在said两种：

Matched ['Amelia said "I am a camel"']!
$VAR1 = {
          'said' => [
                      '\'Amelia said "I am a camel"\''
                    ]
        };

我想我理解这一点，但我也知道这里有人真正触及C代码才能实现。 :)

而且，当我写这篇文章时，我认为我应该重载STORE领带为%-找出来，但后来我必须找出如何做到这一点。

Answer 1

在玩完这个之后，我很满意我在问题中所说的是对的。 每次调用(?PARNO)都会得到一个完整且独立的匹配变量集，它在运行结束时会丢弃。

您可以通过使用模式匹配运算符外部的数组并在重复子模式的末尾按下它来获取每个子模式中匹配的所有内容，如下例所示：

#!/usr/bin/perl
# nested_carat_n.pl

use v5.10;

$_ =<<'HERE';
Outside "Top Level 'Middle Level "Bottom Level" Middle' Outside"
HERE

my @matches;

say "Matched!" if m/
    (?(DEFINE)
        (?<QUOTE_MARK> ['"])
        (?<NOT_QUOTE_MARK> [^'"])
    )
    (
    (?<quote>(?&QUOTE_MARK))
        (?:
            (?&NOT_QUOTE_MARK)++
            |
            (?R)
        )*
    \g{quote}
    )
    (?{ push @matches, $^N })
    /x;

say join "\n", @matches;

我将在掌握Perl的第2章深入介绍它，你可以免费阅读（至少有一段时间）。