使用awk或sed查找特定模式并打印完整文本块

Question

如何在文本块中找到特定数字并打印以关键字"BEGIN"开头并以"END"结尾的完整文本块？ 基本上这是我的文件的样子：

BEGIN
A: abc
B: 12345
C: def
END

BEGIN
A: xyz
B: 56789
C: abc
END

BEGIN
A: ghi
B: 56712
C: pqr
END

[...]

如果我正在寻找'^B: 567' ，我想得到这个输出：

BEGIN
A: xyz
B: 56789
C: abc
END

BEGIN
A: ghi
B: 56712
C: pqr
END

我可以在这里使用grep（ grep -E -B2 -A2 "^B: 567" file ），但我想得到一个更通用的解决方案。 我想awk或sed可能会这样做！？

谢谢！ :)

Answer 1

$ awk -v RS= -v ORS='\n\n' '/\nB: 567/' file
BEGIN
A: xyz
B: 56789
C: abc
END

BEGIN
A: ghi
B: 56712
C: pqr
END

注意B之前的\\n以确保它出现在一行的开头。这取代了你原来的^ start-of-string字符，因为现在每一行都不是它自己的字符串。 您需要在上面设置ORS以重新插入记录之间的空白行。

Answer 2

这可能适合你（GNU sed）：

sed -n '/^BEGIN/{x;d};H;/^END/{x;s/^B: 567/&/mp}' file

或这个：

sed -n '/^BEGIN/!b;:a;$!{N;/\nEND/!ba};/\nB: 567/p' file

Answer 3

您可以取消RS以在空行中分割记录并检查字符串是否在整个块中匹配：

awk 'BEGIN { RS = "" } /\nB:[[:space:]]+567/ { print $0 ORS }' infile

它产生：

BEGIN
A: xyz
B: 56789
C: abc
END 

BEGIN
A: ghi
B: 56712
C: pqr
END

Answer 4

这awk应该工作：

awk -v s='B: 567' '$0~s' RS= file
BEGIN
A: xyz
B: 56789
C: abc
END
BEGIN
A: ghi
B: 56712
C: pqr
END

Answer 5

有点长，但RS技巧已经发布:-)

BEGIN {found=0;start=0;i=0}


/BEGIN/ {
    start=1
    delete a
}

/.*567.*/ {found=1}

{
    if (start==1) {
        a[i++]=$0
    }
}

/END/ {
    if (found) {
        for (i in a)
            print a[i]
    }
    found=0
    start=0
    delete a
}

输出：

$ awk -f s.awk input
BEGIN
A: xyz
B: 56789
C: abc
END
BEGIN
A: ghi
B: 56712
C: pqr
END

Answer 6

perl -lne 'if(/56789/){$f=1}
           push @a,$_;
           if(/END/){
              if($f){print join "\n",@a}
           undef @a;$f=0}' your_file