如何使用 Z3 和 CVC4 与 SMT -LIB 证明二面体群 D3 的定理

Question

在之前的一篇文章中，证明了使用 Z3 SMT-LIB 的二面体群 D3 的一个定理。 在这篇文章中，我们尝试使用以下 SMT-LIB 代码同时使用 Z3 和 CVC4 来证明这样的定理：

(set-logic AUFNIRA)
(set-option :produce-models true)
(set-option :incremental true)
(declare-sort S 0)
(declare-fun f (S S) S)
(declare-fun g (S) S)
(declare-fun E () S)
(declare-fun R1 () S)
(declare-fun R2 () S)
(declare-fun R3 () S)
(declare-fun R4 () S)
(declare-fun R5 () S)
(assert (forall ((x S))
            (= (f x E) x)))
(assert (forall ((x S))
            (= (f E x) x)))               
(assert (= (f R1 R1) R2))
(assert (= (f R1 R2) E))
(assert (= (f R1 R3) R4))
(assert (= (f R1 R4) R5))
(assert (= (f R1 R5) R3))
(assert (= (f R2 R1) E))
(assert (= (f R2 R2) R1))
(assert (= (f R2 R3) R5))
(assert (= (f R2 R4) R3))
(assert (= (f R2 R5) R4))
(assert (= (f R3 R1) R5))
(assert (= (f R3 R2) R4))
(assert (= (f R3 R3) E))
(assert (= (f R3 R4) R2))
(assert (= (f R3 R5) R1))
(assert (= (f R4 R1) R3))
(assert (= (f R4 R2) R5))
(assert (= (f R4 R3) R1))
(assert (= (f R4 R4) E))
(assert (= (f R4 R5) R2))
(assert (= (f R5 R1) R4))
(assert (= (f R5 R2) R3))
(assert (= (f R5 R3) R2))
(assert (= (f R5 R4) R1))
(assert (= (f R5 R5) E))
(assert (= (g E) E))
(assert (= (g R1) R2))
(assert (= (g R2) R1))
(assert (= (g R3) R3))
(assert (= (g R4) R4))
(assert (= (g R5) R5))
(check-sat)
(get-model)
(get-value ((f (f R3 R1) (g R3))))
(get-value (R2))
(assert (not (= (f (f R3 R1) (g R3)) R2))) 
(check-sat) 

当使用 Z3 或 CVC4 执行此代码时，将获得正确的结果。 在此处使用 Z3 在线运行此代码

问题是：

1. 在 Z3 的情况下， unsupported ; :incremental消息unsupported ; :incremental unsupported ; :incremental产生。 这个消息似乎不会改变结果，为什么？

2. 在 CVC4 的情况下，会产生一条消息unknown而 Z3 产生sat 。 同样，这条消息似乎不会改变结果，为什么？

3. 如何使用 Mathsat 执行 SMT-LIB 代码。

Answer 1

关于问题 1，选项:incremental不是 SMT-LIB 2.0 标准的一部分。 该标准定义/建议了所有求解器都应支持的一小组选项，并且:incremental不是其中之一。 这可能是 CVC4 特定的选项。 Z3 只是忽略此命令。 此外，Z3 不需要用户启用增量求解。

关于问题 2，SMT-LIB 2.0 标准说check-sat有 3 个可能的输出： unsat 、 sat和unknown 。 当求解器无法确定断言集是否可满足时，将使用unknown结果。 一些求解器即使在生成unknown时也会生成“候选模型”。

据我所知，MathSAT 5 还不支持量词。 然而，这应该在未来改变。

Answer 2

Mathsat 似乎产生了正确的结果，但它生成了消息：