比较两个文件夹中的文件数

Question

我想验证两个文件夹具有相同数量的文件。

例如，如果文件夹c:\\Users\\abc\\INBOX中有5个文件，我想验证文件夹c:\\Users\\abc\\OUTBOX中也有5个文件

我该如何实现？

Answer 1

尝试这样的事情：

@echo off

set $Folder1="c:\Users\abc\INBOX"
set $folder2="c:\Users\abc\OUTBOX"
set $count=1

setlocal EnableDelayedExpansion

for %%x in (%$Folder1% %$Folder2%) do (
for /f "tokens=1 delims= " %%a in ('dir %%x ^| find /i "File(s)"') do (
set $Total!$Count!=%%a)
set /a $Count+=1)

If %$Total1% Equ %$Total2% (echo Same number of files) else (echo Different number of files)

如果您的系统不是英语，则必须根据系统语言（例如：法语中的“ Fichier（s）”）更改"File"

编辑：

要将更多目录与“第一”进行比较：

@echo off

set $Folder1="c:\Users\abc\INBOX"

set $folder2="c:\Users\abc\OUTBOX"
set $Folder3=c:\Users\abc\OUTBOX\PROC
set $Folder4=c:\Users\abc\OUTBOX\PEND
set $Count=0

setlocal EnableDelayedExpansion

for %%x in (%$Folder1% %$Folder2% %$Folder3% %$Folder4%) do (
     for /f "tokens=1 delims= " %%a in ('dir %%x /a-d ^| find /i "File(s)"') do (
               call:test %%x %%a
               if !$count! Equ 0 set $Ref=%%a
                                set $Count=1))
exit/b

:test

if !$count! Equ 1 (
    If "%$Ref%" Equ "%2" (echo %$Folder1% SAME %1) else (echo %$Folder1% DIFFERENT %1))

Answer 2

@echo off

    setlocal enableextensions disabledelayedexpansion

    call :getNumberOfFilesInFolderList nINBOX "c:\Users\abc\INBOX"
    call :getNumberOfFilesInFolderList nFiles "c:\Users\abc\OUTBOX" "c:\Users\abc\OUTBOX\PROC" "c:\Users\abc\OUTBOX\PEND"

    if %nINBOX% EQU %nFiles% (
        echo SAME number of files
    ) else (
        echo DIFFERENT number of files
    )

    endlocal
    exit /b

:getNumberOfFilesInFolderList variable folder1 [[folder2] ... ]
    setlocal enableextensions disabledelayedexpansion
    set "variable="
    set /a "total=0"
    for %%a in (%*) do if not defined variable (set "variable=%%~a" ) else (
        for /f %%b in ('dir /a-d "%%~a" 2^>nul ^| findstr /r /c:"^[ ][ ][ ]*[0-9]"') do set /a "total+=%%b"
    )
    endlocal & set "%~1=%total%" & echo %total%
    goto :eof

Answer 3

这应该比较两个文件夹。

@echo off
set aa=0&set bb=0
for %%a in ("c:\Users\abc\INBOX\*")  do set /a aa+=1
for %%a in ("c:\Users\abc\OUTBOX\*") do set /a bb+=1

if %aa% EQU %bb% (
     echo they have the same number of visible files.
  ) else (
     echo the file count is different
)