在CUDA __constant__内存和多GPU上？

Question

在共享内存编程模型中，任何全局变量对于每个线程都是可见的。

在CUDA中，以类似方式声明的常量内存，例如共享内存系统中的全局变量，这让我有些担心：

考虑以下代码：

__constant__ int array[1024];

void hostFunction(int DeviceID, cudaStream_t streamIdx)
{
    cudaSetDevice(DeviceID);
    someKernel<<<100,1024,0, streamIdx>>>(...);
    //The function someKernel will use data stored in array[] on current device;
};

然后， array[]的内容是否在每个cuda上下文/设备本地，以便我们可以安全地更新每个设备的“私有” array[]而不必担心更改在其他cuda设备上分配的array[]的值？

顺便说一句：我在网站上搜索了一些相关问题，但是从这些问题中我都找不到明确的答案。

Answer 1

然后，array []的内容是否在每个cuda上下文/设备本地，以便我们可以安全地更新每个设备的“私有” array []而不必担心更改在其他cuda设备上分配的array []的值？

是的，单行代码

__constant__ int array[1024];

在程序访问的每个设备上创建一个分配。

然后，您可以使用以下命令分别在每个设备上加载__constant__内存：

cudaSetDevice(0);
cudaMemcpyToSymbol(array, my_device_0_constant_data, 1024*sizeof(int));

并对您要使用的每个设备重复以上操作。

可以对__device__变量做出类似的陈述。

这是一个完整的示例：

$ cat t223.cu
#include <stdio.h>

#define cudaCheckErrors(msg) \
    do { \
        cudaError_t __err = cudaGetLastError(); \
        if (__err != cudaSuccess) { \
            fprintf(stderr, "Fatal error: %s (%s at %s:%d)\n", \
                msg, cudaGetErrorString(__err), \
                __FILE__, __LINE__); \
            fprintf(stderr, "*** FAILED - ABORTING\n"); \
            exit(1); \
        } \
    } while (0)

__constant__ int my_const_data;

__device__ int my_dev_data;

__global__ void my_kernel(int my_dev){

  printf("device %d constant data is: %d\n", my_dev, my_const_data);
  printf("device %d __device__ data is: %d\n", my_dev, my_dev_data);
}

int main(){

  int num_dev = 0;
  cudaGetDeviceCount(&num_dev);
  cudaCheckErrors("get device count fail");
  if (num_dev == 0) {printf("no cuda devices found!\n"); return 1;}
  for (int i = 0; i < num_dev; i++){
    int cdata = i;
    int ddata = 10*i;
    cudaSetDevice(i);
    cudaMemcpyToSymbol(my_const_data, &cdata, sizeof(int));
    cudaMemcpyToSymbol(my_dev_data, &ddata, sizeof(int));
    cudaCheckErrors("memcpy to symbol fail");}
  for (int i = 0; i < num_dev; i++){
    cudaSetDevice(i);
    my_kernel<<<1,1>>>(i);
    cudaDeviceSynchronize();}
  cudaCheckErrors("kernel fail");
  return 0;
}

$ nvcc -arch=sm_20 -o t223 t223.cu
$ ./t223
device 0 constant data is: 0
device 0 __device__ data is: 0
device 1 constant data is: 1
device 1 __device__ data is: 10
device 2 constant data is: 2
device 2 __device__ data is: 20
device 3 constant data is: 3
device 3 __device__ data is: 30
$