在 Haskell 中生成一组布尔变量的所有组合

Question

我正试图在 haskell 中绕过列表 monad。 给定指定布尔变量的字符串列表，我试图生成所有可能命题的列表。

例如调用：

mapM_ print $ allPropositions ["a","b"]

将产生以下结果：

[("a",True),("b",True)]
[("a",True),("b",False)]
[("a",False),("b",True)]
[("a",False),("b",False)]

我已经设法使用列表推导和递归使用以下代码来做到这一点

allPropositions :: [String] -> [[(String,Bool)]]
allPropositions [] = [[]]
allPropositions (x:xs) = [(x,True):r | r <- allPropositions xs] ++ [(x,False):r | r <- allPropositions xs]

我正在寻找一种方法来使用类似于以下代码段的 do 表示法，但具有可变数量的输入。 有没有办法做到这一点（嵌套单子，...）？

allPropositions' = do
    a <- [True, False]
    b <- [True, False]
    return([("a",a),("b",b)])

Answer 1

你需要的是sequence :: Monad m => [ma] -> m [a] 。

特别是，对于[] monad， sequence接受一个包含n个列表的列表，并生成所有n长度的列表，一次从每个列表中提取一个元素。

sequence [ [1,2,3], [4,5], [6] ] = 
   [ [1,4,6], [1,5,6], [2,4,6], [2,5,6], [3,4,6], [3,5,6] ]

这在您的特定情况下有帮助，因为如果您有一个包含n字符串的列表，您可以轻松地为每个字符串生成可能性：

map (\s -> [(s,True), (s,False)] ["a", "b", "c"] = 
   [ [("a", True), ("a", False) ]
   , [("b", True), ("b", False) ]
   , [("c", True), ("c", False) ]
   ]

现在你只需要从每个列表中选择一个来让你的命题为每个变量保存一个真值：

sequence (map (\s -> [(s,True), (s,False)] ["a", "b", "c"]) = 
   [ [("a", True), ("b", True), ("c", True)]
   , [("a", True), ("b", True), ("c", False)]
   , [("a", True), ("b", False), ("c", True)]
   , [("a", True), ("b", False), ("c", False)]
   , [("a", False), ("b", True), ("c", True)]
   , [("a", False), ("b", True), ("c", False)]
   , [("a", False), ("b", False), ("c", True)]
   , [("a", False), ("b", False), ("c", False)]
   ]

sequence (map f xs)经常出现，以至于有一个名字：

mapM f xs = sequence (map f xs)
-- or, point-free style
mapM f = sequence . map f

所以你想要的功能只是

allPropositions vs = mapM (\v -> [(v,True),(v,False)]) vs
-- or, equivalently
allPropositions = mapM (\v -> [(v,True),(v,False)])
-- or, equivalently
allPropositions = mapM $ \v -> [(v,True),(v,False)]
-- or, equivalently, with -XTupleSections
allPropositions = mapM $ \v -> map (v,) [True, False]

Answer 2

这就是我将如何做到的：

allPropositions :: [a] -> [[(a, Bool)]]
allPropositions = foldr (\x xs -> (:) <$> [(x,True),(x,False)] <*> xs) [[]]

您根本不需要 monad 的全部功能。 你所需要的只是applicative functors 。

这是发生了什么：

1. 对于基本情况，结果是[[]] （即allPropositions [] = [[]] ）。
2. 对于归纳的情况，结果是⟦(:) [(x,True),(x,False)] xs⟧ 。 请注意，双方括号（即⟦⟧ ）表示应用函子的上下文（在本例中为[] ）。

尽管rampion 的答案是正确的，但它使用了作为单子函数的sequence和mapM 。 但是，正如我之前所说，在这种情况下您不需要 monad 的全部功能。

Answer 3

如果您不想要 monad 的全部功能，您仍然可以使用sequenceA 。