Excel中。 如何计算重复细胞的数量？

Question

我需要在Excel中编写过滤器数据。 如何计算重复细胞的数量？

示例我在列中有数据

    0
    0
    1
    0
    1
    1
    0
    1
    1
    1
    0
    1
    1
    1
    1

产量

Count 1 = 10
Count 1;1 = 4
Count 1;1;1 = 2 
Count 1;1;1;1 = 1 

Answer 1

在A1：A15中使用您的值并选择要考虑的连续1的数量（例如在B1中为3）时，在C1中使用以下数组公式** ：

=SUM(INT(FREQUENCY(IF(A$1:A$15=1,ROW(A$1:A$15)),IF(A$1:A$15=0,ROW(A$1:A$15)))/B1))

抄写下来，以得出类似的结果，以改变B2，B3等中要考虑的连续1的数量。

作为此操作方式的一个示例，使用给定的原始数据并使用B1 = 2，我们可以看到公式将变为：

=SUM(INT(FREQUENCY({FALSE;FALSE;3;FALSE;5;6;FALSE;8;9;10;FALSE;12;13;14;15},{1;2;FALSE;4;FALSE;FALSE;7;FALSE;FALSE;FALSE;11;FALSE;FALSE;FALSE;FALSE})/B1))

现在应该清楚为data_array和bins_array选择IF语句的原因，其中每个元素内的元素是另一个元素的补充。

这样，当我们将这些数组传递给FREQUENCY时，我们将获得由每个分组中的1数量组成的输出，上面的解析为：

=SUM(INT({0;0;1;2;3;4}/B1))

其余的都相当简单。

问候

**数组公式的输入方式与“标准”公式的输入方式不同。 首先按住CTRL和SHIFT，然后再按Enter，而不是仅按ENTER。 如果操作正确，您会注意到Excel在公式周围使用大括号{}（尽管不要尝试自己手动插入大括号）。

Answer 2

步骤1：将单元格中的所有值作为字符串连接到一个单元格中（对于本示例，我假设您的数据在A列中，而连接在单元格B1中）。
1（a）在单元格B1中，输入公式=CONCATENATE(A1,A2,A3,...,A_) 。 如果存在多个单元格，这将非常耗时。
1（b）或者，通过Google的快速搜索产生了这篇文章， 该文章提供了一种相当快速（但手动）的方法来连接大范围的值。

步骤2：计算上述串联中较小字符串的出现次数。
2.1将要搜索的字符串放在单元格中（对于本示例，我将假定单元格为C1）
2.2在单元格D1中，输入公式=(LEN($B$1)-LEN(SUBSTITUTE($B$1,C1,"")))/LEN(C1) 。 通过搜索字符串并将每次出现的目标字符串（C1）替换为空格（“”）并测量长度差，可以实现此目的。
2.3重复您要搜索的每个值

上面示例中的结果值：

       A:   B:                 C:      D:
 1 :   0    001011011101111    1       10
 2 :   0                       11      4
 3 :   1                       111     2
 4 :   0                       1111    1
 5 :   1    
 6 :   1    
 7 :   0    
 8 :   1    
 9 :   1    
 10:   1    
 11:   0    
 12:   1    
 13:   1    
 14:   1    
 15:   1