在Haxe中，如何使用宏向模块添加类型/类？

Question

我想基于目录中的一些文件动态地向给定模块添加一些新类型。

我本质上是试图在模块的底部填充一堆@:file(...)嵌入类。

//This is the module I'm targeting to append embedded ByteArray subtypes (see below)
@:build(macros.AutoEmbed.build("some/folder/"))
class Embeds {
    //Empty on purpose, just let the Macro do its thing!
}


// At "macro-time", it should generate these:

@:file("some/folder/ui_main.xml")
class UI_MAIN_XML extends flash.utils.ByteArray { }

@:file("some/folder/config.template.json")
class CONFIG_TEMPLATE_JSON extends flash.utils.ByteArray { }

到目前为止我能找到的是我可能必须改变Embeds.hx模块。 所以我研究了Context.getModule( Context.getLocalModule() ) 。 我也研究过TypeDefinition因为它似乎是从头开始定义新类型的唯一方法。

Context.getModule(...)的问题是它返回一个数组Array<Type> ，而不是Array<TypeDefinition> ，所以我不能为它添加新的TypeDefinition （另外我必须弄清楚如何编写那些， 呃 ）。 这对我来说可能是一个不好的假设，但我想通过简单地添加更多的TypeDefinition我可以动态地在模块中提供更多类型。

你可以说，我对Macros还是很新的！

编辑

确实，我可以使用FileSystem / File写入解决方案在编译时动态编写/覆盖新的Embeds.hx文件，但这意味着在IDE自动完成之前需要至少编译一次才能获取生成的Embeds.*类（我的情况下是FlashDevelop）。 加上任何时候在定义的文件夹中删除新文件，同样的问题：您需要在IDE检测到之前先编译。 是的，我真的很喜欢自动完成:)

Answer 1

从构建宏开始是好的。 您可以构建类字段并创建类型。

这是一个只生成一种类型和相应字段的宏：

#if macro
import haxe.macro.Context;
import haxe.macro.Expr;

class AutoEmbed
{
    macro static public function build(folder:String):Array<Field>
    {
        var inClass = Context.getLocalClass().get();

        // explore folder and create those:

        var fileName = 'resource/strings.json';
        var name = fileName.split('/').pop().split('.').join('_');

        var valueExpr = makeType(inClass.pack, name, fileName);

        var field = {
            name: name,
            access: [APublic, AStatic, AInline],
            kind: FVar(null, valueExpr),
            pos: Context.currentPos()
        }

        return [field];
    }

    static function makeType(pack:Array<String>, name:String, fileName:String) 
    {
        var pos = Context.currentPos();
        var className = name.toUpperCase();

        var cdef = macro class Tmp extends haxe.io.BytesData { }
        cdef.pack = pack.copy();
        cdef.name = className;

        cdef.meta = [{
            name: ':file',
            params: [Context.makeExpr(fileName, pos)],
            pos: pos
        }];

        haxe.macro.Context.defineType(cdef);

        return {
            expr:EConst(CIdent(className)),
            pos:pos
        };
    }
}
#end

现在使用它：

trace(Embed.strings_json); // [ByteArray]

@:build(AutoEmbed.build('some/folder'))
class Embeds
{
    // generate field strings_json pointing to class STRINGS_JSON
}

Answer 2

您可以使用初始化宏： http ： //haxe.org/manual/macro-initialization.html在键入之前执行宏。

然后，为了实际创建新的类/模块，您可以使用Context.defineModule： http ： //api.haxe.org/haxe/macro/Context.html#defineModule