内部加入持久性还是我应该使用 esqueleto？

Question

我有这个片段描述Notification和Notified实体：

Notification
  type          NotiType
  release       ReleaseId
  date          UTCTime
Notified
  aboutWhat     NotificationId
  unread        Bool
  user          UserId

现在我想写这个：

-- | Mark specified notification as already seen by specific user. Note that
-- we use 'ReleaseId' to select notification, so this may result in several
-- notifications marked as “read” if they happen to be about the same
-- release. This is generally what you want.

markAsRead
  :: ReleaseId         -- ^ Release in question
  -> UserId            -- ^ User who has seen mentioned release
  -> SqlPersistM ()
markAsRead release user = do
  ns <- selectKeysList [ NotificationRelease ==. release ] []
  updateWhere [ NotifiedAboutWhat <-. ns
              , NotifiedUnread    ==. True
              , NotifiedUser      ==. user ]
              [ NotifiedUnread    =.  False ]

这是可行的，但是将通知列表提取为列表，然后使用它来选择另一个表中的内容……这并不完全正确。 显然我需要在这里加入，然后我将能够有效地更新所有内容。

纯persistent怎么做？ 在这种情况下， persistent执行此类任务是否有可能？这是一个好主意吗？ 我应该改用esqueleto吗？ 看起来我需要学习不同的 DSL 才能使用它，所以我不确定是否要切换。

如何使用persistent （如果可能）正确编写markAsRead ？

Answer 1

是的，如果您想进行连接，则是 Esqueleto。 如果您的数据库和您的数据建模支持，持久性可以很好地嵌入数据。

Answer 2

正如 Greg 所提到的，Esqueleto 是要走的路。 您可以尝试阅读其主要模块文档。

目前 Esqueleto 不支持UPDATE的连接。 但是，您可以使用子查询达到相同的效果。

未经测试的代码可帮助您入门：

-- | Mark specified notification as already seen by specific user. Note that
-- we use 'ReleaseId' to select notification, so this may result in several
-- notifications marked as “read” if they happen to be about the same
-- release. This is generally what you want.
markAsRead
  :: ReleaseId         -- ^ Release in question
  -> UserId            -- ^ User who has seen mentioned release
  -> SqlPersistM ()
markAsRead release user = 
  update $ \n -> do
  set n [ NotifiedUnread =. val False ]
  where_ $
    n ^. NotifiedUnread  ==. val True &&.
    n ^. NotifiedUser    ==. val user &&.
    n ^. NotifiedAboutWhat `in_` 
      (subList_select $
       from $ \t -> do
       where_ $ t ^. NotificationRelease ==. val release
       return $ t ^. NotificationId)