[英]XSLT to transform XML based on tag content value
我想编写一个可以转换XML的XSLT,如下所示:
<Companies>
<Company>
<CompanyId>1</CompanyId>
<CompanyType>1</CompanyType>
</Company>
<Company>
<CompanyId>2</CompanyId>
<CompanyType>2</CompanyType>
<ParentCompanyId>1</ParentCompanyId>
</Company>
</Companies>
变成这样的XML:
<Companies>
<Company>
<CompanyId>1</CompanyId>
<CompanyType>1</CompanyType>
<Company>
<CompanyId>2</CompanyId>
<CompanyType>2</CompanyType>
</Company>
</Company>
</Companies>
我该怎么做?
(之所以包含公司类型,是因为我可以直接从中得出节点的深度,这意味着深度为X的所有Company
节点的类型都为Y)
使用键选择当前公司的子公司很容易做到。 这对于任何深度的嵌套都可以递归工作。 不需要CompanyType
。
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:key name="child-by-parent" match="Company" use="ParentCompanyId" />
<xsl:template match="/Companies">
<xsl:copy>
<!-- select progenitors -->
<xsl:apply-templates select="Company[not(ParentCompanyId)]" />
</xsl:copy>
</xsl:template>
<xsl:template match="Company">
<xsl:copy>
<xsl:copy-of select="CompanyId | CompanyType"/>
<!-- select children -->
<xsl:apply-templates select="key('child-by-parent', CompanyId)"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.