如何对2D数组Perl排序？

Question

可能是我缺少了一些东西。 首先，这对我来说似乎太容易了。我以为我可以使用map{}sort{}map{}轻松实现它，但现在对我来说变得很复杂。

所以，最后的问题是我有一个数组：

@array=(['b','e','d'],['s','a','f'],['g','i','h']);

我想要排序的数组像

@sorted_array=(['a','f','s'],['b','d','e'],['g','h','i']);

我写

##sort based on columns########
my @sorted_array= map{my @sorted=sort{$a cmp $b}@$_;[@sorted]}@array;

###sort on rows####
my @sorted_array= map{$_->[0]}sort{$a->[1] cmp $b->[1]} map{[$_,"@$_"]}@array;

但是我不确定如何将其包装为一个（行和列）。 我可以使用Schwartzian变换来实现吗？

Answer 1

是的，您可以使用它，

use strict;
use warnings;

my @array =( [qw(b e d)], [qw(s a f)], [qw(g i h)] );

my @sorted_array = 
map { $_->[0] }
sort {
  $a->[1] cmp $b->[1]
}
map {
  my $r = [ sort @$_ ];
  [$r, "@$r"];
}
@array;

use Data::Dumper;
print Dumper \@sorted_array;

产量

$VAR1 = [
      [
        'a',
        'f',
        's'
      ],
      [
        'b',
        'd',
        'e'
      ],
      [
        'g',
        'h',
        'i'
      ]
    ];

Answer 2

这是两种不同的类型。 首先，您要对内部数组进行单独排序，然后可以按每个内部数组的第一个元素对外部数组进行排序。

use List::UtilsBy qw( sort_by );

my @array =( [qw(b e d)], [qw(s a f)], [qw(g i h)] );

# sort the inner ones individually
@$_ = sort @$_ for @array;

# sort the whole by the first element of each
my @sorted_array = sort_by { $_->[0] } @array;

或者，如果您希望一次性完成所有操作并避免临时更改，请执行以下操作：

my @sorted_array = sort_by { $_->[0] }
                   map { [ sort @$_ ] } @array;