N-Queens 示例程序奇怪的输出

Question

我尝试使用squeen.icl示例中的代码。 当我尝试使用BoardSize :== 11 ，没有问题。 但是当我将其更改为12 ，输出为[ 。 为什么？ 如何解决？

module squeen
import StdEnv

BoardSize :== 12

Queens::Int [Int] [[Int]] -> [[Int]]
Queens row board boards
    | row>BoardSize =  [board : boards]
    | otherwise     =  TryCols BoardSize row board boards

TryCols::Int Int [Int] [[Int]] -> [[Int]]
TryCols 0 row board boards =  boards
TryCols col row board boards
    | Save col 1 board  =   TryCols (col-1) row board queens
    | otherwise         =   TryCols (col-1) row board boards
where   queens  = Queens (row+1) [col : board] boards

Save::!Int !Int [Int] -> Bool
Save  c1 rdiff [] =  True
Save  c1 rdiff [c2:cols]
    | cdiff==0 || cdiff==rdiff || cdiff==0-rdiff    =   False
    | otherwise                                     =   Save c1 (rdiff+1) cols
where   cdiff   = c1 - c2


Start::(Int,[Int])
Start   =   (length solutions, hd solutions)
where   solutions   = Queens 1 [] []

Answer 1

这是因为堆上的空间不足。 默认情况下，Clean 程序的堆设置为 2M。 当然，您可以更改此设置。 从命令行使用clm ，您可以将-h 4M添加到其命令行或 clean 程序本身的命令行。 如果您使用的是 Clean IDE，则可以通过“项目选项”、“应用程序”更改堆大小。

(仍然打印(这是我得到的，而不是[ ) 的原因如下。一个 Clean 程序将输出尽可能多的输出，而不是等到整个输出已知。这意味着，对于例如，像Start = [0..]这样的简单行会向您的终端发送垃圾邮件，而不是等到整个无限列表都在内存中后再打印它。在squeen.icl的情况下，Clean 看到 Start 的结果将是一个元组，因此直接打印左括号。但是，当尝试计算元组的元素（ length solutions和hd solutions ）时，堆填满，使程序终止。

我不知道当你在 Windows 上得到一个完整的堆时会是什么样子，但在 Linux(/Mac) 上，它看起来像这样：

$ clm squeen -o squeen && ./squeen -h 2M
Linking squeen
Heap full.
Execution: 0.13  Garbage collection: 0.03  Total: 0.16
($

请注意，元组大括号在最后一行。 因此，在使用终端时很容易发现此错误。

有趣的是，由于length利用了尾递归，因此即使使用小堆也可以计算元组的第一个元素（您可以通过将第二个元素替换为[]来尝试此操作）。 元组的第二个元素也可以在一个小堆上计算（用0替换第一个元素）。

关键是长度在头部之前计算，因为它必须首先打印。 虽然使用正常length调用列表的部分是垃圾收集（在迭代前 100 个元素后，它们可以被丢弃，允许使用较小的堆），但hd调用确保列表的第一个元素不会被丢弃。 如果第一个元素没有被丢弃，那么第二个元素、第三个元素等都不会被丢弃。因此，整个列表都保存在内存中，而这实际上并不是必需的。 翻转length和hd调用解决了这个问题：

Start :: ([Int], Int)
Start = (hd solutions, length solutions)
where solutions = Queens 1 [] []

现在，在调用hd之后，没有理由将整个列表保留在内存中，因此length可以丢弃它迭代过的元素，并且堆不会填满。