Prolog：超出本地堆栈错误

Question

考虑以下代码（摘自RP Suri的Prolog简介 ）：

/* A set of father-child pairs declared */
father("Motilal", "Jawaharlal").
father("Motilal", "Vijayalakshmi").
father("Motilal", "Krishna").
father("Jawaharlal", "Indira").
father("Ranjit", "Tara").
father("Ranjit", "Lekha").
father("Ranjit", "Rita").
father("Feroz", "Sanjay").
father("Feroz", "Rajiv").
father("Sanjay", "Varun").
father("Rajiv", "Rahul").
father("Rajiv", "Priyanka").

/* Mothers declared */
wife_of("Swaruprani", "Motilal").
wife_of("Kamla", "Jawaharlal").
wife_of("Vijayalakshmi", "Ranjit").
wife_of("Indira", "Feroz").
wife_of("Maneka", "Sanjay").
wife_of("Sonia", "Rajiv").
wife_of("Priyanka", "Robert").

/* Predicates declared */
mother(M, C) :- wife_of(M, Hus) , father(Hus, C).

parent(P, C) :- mother(P, C) ; father(P, C).

ancestor(X, Y) :- parent(X, Y).
ancestor(X, Y) :- ancestor(X, Z) , parent(Z, Y).

现在，如果我查询

ancestor("Motilal", X)

我得到的输出为：

?- ancestor("Motilal", X).
X = "Jawaharlal" ;
X = "Vijayalakshmi" ;
.
.
.
X = "Priyanka" ;

（这是正确的输出），此后程序停止，几秒钟后，我收到消息：

ERROR: Out of local stack

当我查询时发生类似的事情

ancestor(X, "Motilal").

这应该什么也不会返回，但是提示会再次消失几秒钟，然后出现相同的错误消息。 代码有什么问题？

Answer 1

要理解您的代码中的问题，无需查看整个程序。 取而代之的是，查看导致非终止的微小部分就足够了：

?- ancestor(X, 'Motilal'), false.

ancestor(X, Y) :- false, parent(X, Y).
ancestor(X, Y) :- ancestor(X, Z) , false, parent(Z, Y).

该片段尚未终止，因此整个程序也不会终止。 不管您在其他部分写了什么！ 因此，您需要在其余部分中进行一些更改。 否则，错误将继续存在。

有关更多信息，请参见failure-slice 。

您看到需要更改的内容了吗？

将目标parent(Z, Y)放在前面！

顺便说一句，在Prolog中，在这种情况下通常使用单引号原子，因为这样效率更高！