如果单元格包含Excel，则将其写入另一个

Question

所以基本上我需要创建学生在一个单元格中完成的课程列表（1,10,15,16）。 课程的最大数量为50.课程由其编号确认

我想要做的是创建一个公式，显示在另一个单元格中完成的所有课程。 我的意思是：在一个单元格中，我写了一个学生已完成的课程，例如1,5,7，而在另一个单元格中，结果将自动为所有数字，最多50个除了完成的那个，因此单元格将是2,3， 6,8 ....

我试过了

=ISNUMBER(SEARCH(substring,text))

但这并没有给我带来好结果。

Answer 1

要做到这一点，我们需要将字符串拆分为,然后用什么都替换thos值。

这个UDF做你想要的：

Function LessonsLeft(rng As Range) As String
If rng.Count > 1 Then Exit Function
Dim spltStr() As String
Dim i As Long
spltStr = Split(rng.Value, ",")
LessonsLeft = ",1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,"
For i = LBound(spltStr) To UBound(spltStr)
    LessonsLeft = Replace(LessonsLeft, "," & spltStr(i) & ",", ",")
Next i
LessonsLeft = Mid(LessonsLeft, 2, Len(LessonsLeft) - 2)
End Function

将它放在工作簿附带的模块中，然后用公式调用它：

=LessonsLeft(A1)

Answer 2

这是另一种选择：

Function MissedLessons(str As String) As String
    Dim resultString As String
    Dim i As Integer

    str = "," & str & ","
    For i = 1 To 50
        If InStr(str, "," & i & ",") = 0 Then
            resultString = resultString & i & ","
        End If
    Next i  

    MissedLessons = Left(resultString, Len(resultString) - 1)
End Function

Answer 3

斯科特解决方案的一点改进：

• 让用户可选择指定课程总数（默认= 50）

• 避免她有代码所有课程数字字符串

如下：

Function LessonsLeft(rng As Range, Optional nLessons As Long = 50) As String
    If rng.count > 1 Then Exit Function
    Dim spltStr() As String
    Dim i As Long

    With CreateObject("Scripting.Dictionary")
        For i = 1 To nLessons
            .Add i, i
        Next
        spltStr = Split(rng.Value, ",")
        For i = LBound(spltStr) To UBound(spltStr)
            .Remove CLng(spltStr(i))
        Next
        LessonsLeft = Join(.keys, ",")
    End With
End Function