![](/img/trans.png)
[英]How to get a list of the distinct element names plus their attribute names using XSLT
[英]XSLT - How to get distinct element names from XML?
我想使用XSLT-1.0从我的XML文件中获得不同的元素名称。
XML:
<forms>
<form1>
<metadata>
<c1>some value</c1>
<c2>some value</c2>
</metadata>
<set>
<subset1>
<c3>some value</c3>
<c4>some value</c4>
<c5>some value</c5>
</subset1>
<subset2>
<c3>some value</c3>
<c4>some value</c4>
<c6>some value</c6>
</subset2>
</set>
</form1>
<form2>
...
</form2>
</forms>
将表单名称传递给XSLT时,输出应如下所示。 例如,如果我传递“ form1”,它应该让我在<form1>
标记内可用的不同数据元素像这样:
c1,c2,c3,c4,c5,c6
另外,我尝试了此XSLT及其返回的内容:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:for-each select=
"//*/*/*[not(../following::*/*
[not(name() = name(current()))]
)
]">
<xsl:value-of select="concat(name(), ' ')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
输出:
set1,set2,subset1,subset2,c3,c4,c6
预期产量:
c1,c2,c3,c4,c5,c6
另外,如何将我的表单名称(即form1
)传递给XSLT?
您可以构建一个本地名称关键字,然后执行以下操作:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />
<xsl:key name="elements" match="*" use="local-name()" />
<xsl:template match="/">
<xsl:for-each select="//*[count(.|key('elements', local-name())[1]) = 1]">
<xsl:value-of select="local-name()" />,
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
基本上,对元素名称进行Muenchian分组。
获得整个文档中所有元素的不同名称的列表相对容易-如Dan Field的答案所示。
将列表限制为metadata
子元素或set
子元素的元素稍微复杂一些。
将列表进一步限制为仅包含要在运行时确定的特定form
后代的元素要复杂得多。
考虑以下样式表:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="selected-form-name">form1</xsl:param>
<xsl:key name="data" match="*" use="name()" />
<xsl:template match="/forms">
<xsl:variable name="selected-form" select="*[name()=$selected-form-name]"/>
<!-- all names in the selected form -->
<xsl:variable name="names-in-form">
<xsl:for-each select="$selected-form/metadata/* | $selected-form/set/*/* " >
<name>
<xsl:value-of select="name()"/>
</name>
</xsl:for-each>
</xsl:variable>
<!-- distinct elements (by name), in the entire document -->
<xsl:variable name="distinct-by-name" select="//*[count(. | key('data', name())[1]) = 1]" />
<output>
<xsl:for-each select="$distinct-by-name[name()=exsl:node-set($names-in-form)/name]">
<item><xsl:value-of select="name()"/></item>
</xsl:for-each>
</output>
</xsl:template>
</xsl:stylesheet>
当应用于以下测试输入时:
XML格式
<forms>
<form1>
<metadata>
<c1>some value</c1>
<c2>some value</c2>
</metadata>
<set>
<subset1>
<c3>some value</c3>
<c4>some value</c4>
<c5>some value</c5>
</subset1>
<subset2>
<c3>some value</c3>
<c4>some value</c4>
<c6>some value</c6>
</subset2>
</set>
</form1>
<form2>
<metadata>
<c7>some value</c7>
<c8>some value</c8>
</metadata>
<set>
<subset3>
<c9>some value</c9>
<c7>some value</c7>
</subset3>
</set>
</form2>
</forms>
结果将是:
<?xml version="1.0" encoding="UTF-8"?>
<output>
<item>c1</item>
<item>c2</item>
<item>c3</item>
<item>c4</item>
<item>c5</item>
<item>c6</item>
</output>
要选择所需的表单,请将一个名为selected-form-name
的参数传递给样式表,其中包含要选择的表单的名称。 如果传递字符串"form2"
,结果将是:
<?xml version="1.0" encoding="UTF-8"?>
<output>
<item>c7</item>
<item>c8</item>
<item>c9</item>
</output>
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.