阿格达：偶数乘积是偶数

Question

我对Agda很陌生。 我正在处理作业中的一个问题。 我已经掌握了其中的大部分，但是我坚持了一个目标。

data Arith : Set where
 Num : ℕ → Arith
 Plus : Arith → Arith → Arith
 Times : Arith → Arith → Arith

eval : Arith → ℕ
eval (Num x) = x
eval (Plus e1 e2) = eval e1 + eval e2 
eval (Times e1 e2) = eval e1 * eval e2

data Even : ℕ → Set where
 zEven : Even 0
 ssEven : {n : ℕ} → Even n → Even (suc (suc n))

-- [PROBLEM 1]

plusEven : ∀ n m → Even n → Even m → Even (n + m)
plusEven zero m x x₁ = x₁
plusEven (suc zero) m () x₁
plusEven (suc (suc .0)) m (ssEven zEven) x₁ = ssEven x₁
plusEven (suc (suc ._)) m (ssEven (ssEven x)) x₁ = ssEven (ssEven (plusEven _ m  x  x₁ ))

-- [PROBLEM 2]

timesEven : ∀ n m → Even n → Even m → Even (n * m)
timesEven zero m x x₁ = zEven
timesEven (suc ._) zero (ssEven x) x₁ =  (timesEven _ zero x x₁)
timesEven (suc ._) (suc ._) (ssEven x) (ssEven x₁) = ssEven ((λ h → {!!}) (timesEven _ _ x x₁))

我要证明的目标是

Goal: Even (.n₁ + suc (suc (.n₁ + .n * suc (suc .n₁))))

我觉得我必须使用plusEven，甚至有些方法。 但是目标看起来并不那么简单。 我让这个问题变得困难了吗？ 还是我在正确的轨道上？ 有没有更简单的方法可以做到这一点？ 我不想解决这个问题。 但是朝正确方向的推动将不胜感激。 我已经坚持了一段时间了。

Answer 1

如果n为偶数，则n * m为偶数，因此m是否为偶数无关紧要，因此您应该放弃此约束。 所以实际定理是（我把n和m隐含了，因为这很方便）

timesEvenLeft  : ∀ {n m} → Even n → Even (n * m)
timesEvenRight : ∀ {n m} → Even m → Even (n * m)

您可以证明n * m ≡ m * n并从前者导出后者定理。 因此，仅需证明第一个。 在递归的情况下，您需要证明在范围上具有Even (n * m) （归纳假设）的Even (suc (suc n) * m) （减少为Even (m + (m + n * m) ））。这将需要另一个引理：

plusDoubleEven : ∀ {n} m → Even n → Even (m + (m + n))

Answer 2

我真的很喜欢这里发布的答案，它们对我有很大帮助。 但我无法更改作业中给出的问题。 我使用发布的答案来解决该问题。 我花了一段时间，看起来有些混乱，但是可以用。 以为我也将其张贴在这里。

timesEven : ∀ n m → Even n → Even m → Even (n * m)
timesEven zero m x x₁ = zEven
timesEven (suc zero) m () x₁
timesEven (suc (suc n)) zero (ssEven x) x₁ = timesEven n zero x x₁
timesEven (suc (suc n)) (suc zero) x ()
timesEven (suc (suc n)) (suc (suc m)) (ssEven x) (ssEven x₁) = ssEven ((λ h → plusEven m (suc (suc (m + n * suc (suc m)))) x₁  (ssEven (plusEven m (n * suc (suc m)) x₁ h))) (timesEven n (suc (suc m)) x (ssEven x₁)))

Answer 3

@ user3237465暗示，一种无需做过多工作即可处理这些引理的干净方法，就是重用自然数的众所周知的属性，这可能不是您对本作业的期望。

从这些众所周知的属性中获取更多收益的一种方法是引入Even的替代定义，您可以证明它等同于归纳定义：

data Even : ℕ → Set where
 zEven  : Even 0
 ssEven : {n : ℕ} → Even n → Even (suc (suc n))

record Even′ (n : ℕ) : Set where
  constructor mkEven′
  field factor    : ℕ
        .equality : n ≡ factor * 2
open Even′

Even⇒Even′ : {n : ℕ} → Even n → Even′ n
(...)
Even′⇒Even : {n : ℕ} → Even′ n → Even n
(...)

然后，您可以通过使用方程式推理，重用标准库中的引理来证明plusEven和timesEven(Right/Left) 。 例如plusEven的证明变为：

plusEven′ : ∀ n m → Even′ n → Even′ m → Even′ (n + m)
plusEven′ n m (mkEven′ p Hp) (mkEven′ q Hq) = mkEven′ (p + q) eq where

  .eq : n + m ≡ (p + q) * 2
  eq = begin
         n + m          ≡⟨ cong₂ _+_ Hp Hq ⟩
         p * 2 + q * 2  ≡⟨ sym (distribʳ-*-+ 2 p q) ⟩
         (p + q) * 2
       ∎

plusEven : ∀ n m → Even n → Even m → Even (n + m)
plusEven n m en em = Even′⇒Even (plusEven′ n m (Even⇒Even′ en) (Even⇒Even′ em))

这是一个具有所有正确输入和所有证明的要点 。