如何创建一个生成一个在Haxe中按名称动态知道的构造函数数组的宏？

Question

我的目标是javascript 。

我有一个在Context.onGenerate（）上运行的宏，它将完全限定类型名称的子集保存到文件中。 然后，另一个构建宏（将在下一个buid上运行）从文件中读取类型名称列表，以便创建向一个类添加静态字段，该类应该在数组中保存这些类型（构造函数）。

我想从第二个宏生成的字段将是这样的：

public static _entities:Array<Class<entities.Entity>> = [
    entities.Foo,
    entities.Bar,
    ...
];

哪个会生成以下javascript

MyClass._entities = [ entities_Foo, entities_Bar, ... ];

现在我尝试手动编写字段以确保一切正常生成 - 确实如此。 但是我无法弄清楚编写宏的正确方法，我不得不添加一个标识符常量作为数组表达式的值，它始终以“未知标识符”错误结束：

var id = { expr: EConst( CIdent( "entities.Foo" ) ), 
           pos: Context.currentPos() };

var ex  = EArrayDecl([ id ]);

fields.push( {
    name    : "_entities",
    access  : [Access.APublic, Access.AStatic ],
    pos     : Context.currentPos(),
    kind    : FVar( 
                macro:Array<Class<entities.Entity>>,

                // I've tried writing it without reification: (see above vars)
                { expr: ex, pos:Context.currentPos() }

                // Or w/ reification:
                macro $a{[ $i{ "entities.Foo" } ]}
              )
});

我正在尝试用宏来完成什么？ 如果是这样可以指导我完成这个步骤？

谢谢。

Answer 1

问题是，你想输出它作为一个标识符，而它实际上是一个点的路径，这应该被表示为链EField s到第一EIdent 。 幸运的是，Haxe有一个方便的“路径” 具体权利：尝试$p{path.split(".")} （其中path是你的"entities.Foo"字符串）。

Answer 2

在对API参考进行了一些挖掘后，我想出了如何做到这一点。 事实证明我需要TypedExpr而不仅仅是标识符常量。

模块类型为TClassDecl的TTypeExpr将产生正确的结果。 所以上面的示例代码变成：

static function getTypeRef( name:String ):Ref<ClassType>
{
    var type = Context.getType( name );

    switch( type )
    {
        default: return Context.error( "Expected a ClassType", Context.currentPos() );
        case TInst( cr, _ ):
            return cr;
    }
}


static function getTypes()
{
    // Obtain ClassType by identifier
    var fooCls = getTypeRef( "entities.Foo" );

    // Get a TypedExpr for the ClassType
    var typedExpr:TypedExpr = {
        expr : TTypeExpr( TClassDecl( fooCls ) ),
        t    : TInst( fooCls, [] ),
        pos  : Context.currentPos()
    };

    // Convert to Expr
    var expr:Expr = Context.getTypedExpr( typedExpr );

    var fields = Context.getBuildFields();

    fields.push( {
        name    : "_entities",
        access  : [Access.APublic, Access.AStatic ],
        pos     : Context.currentPos(),
        kind    : FVar( 
                    macro:Array<Class<entities.Entity>>,
                    macro $a{[ ${expr} ]}   // <- Now it works here
                  )
    });

    return fields;
}