如何创建一个生成一个在Haxe中按名称动态知道的构造函数数组的宏？

Question

I'm targeting javascript .

I have a macro that runs on Context.onGenerate() that saves a subset of fully qualified type names to a file. Then, another build macro (which would run on the next buid) reads the list of type names from the file in order to create add a static field to a class which is supposed to hold those types (constructors) in the array.

The field which I want to generate from the second macro would be something like this:

public static _entities:Array<Class<entities.Entity>> = [
    entities.Foo,
    entities.Bar,
    ...
];

Which would generate the following javascript

MyClass._entities = [ entities_Foo, entities_Bar, ... ];

Now I've tried writing the field manually to make sure everything generates properly--it does. However I can't figure out the right way to write the macro, I get stuck on adding a identifier constant as the value of the array expression, which always ends up in a "Unknown identifier" error:

var id = { expr: EConst( CIdent( "entities.Foo" ) ), 
           pos: Context.currentPos() };

var ex  = EArrayDecl([ id ]);

fields.push( {
    name    : "_entities",
    access  : [Access.APublic, Access.AStatic ],
    pos     : Context.currentPos(),
    kind    : FVar( 
                macro:Array<Class<entities.Entity>>,

                // I've tried writing it without reification: (see above vars)
                { expr: ex, pos:Context.currentPos() }

                // Or w/ reification:
                macro $a{[ $i{ "entities.Foo" } ]}
              )
});

Is what I'm trying to accomplish possible with macros? If so could direct me in the steps to accomplish this?

Thank you.

Answer 1

The problem is that you're trying to output it as a single identifier while it's in fact a dot-path, which should be represented as a chain of EField s to a first EIdent . Luckily, Haxe has a handy "path" reification right for that: try $p{path.split(".")} (where path is your "entities.Foo" string).

Answer 2

After a bit more digging on the API reference I figured out how to do it. It turns out I needed TypedExpr instead of just an identifier constant.

A TTypeExpr with a ModuleType of TClassDecl would yield the correct result. So my example code above becomes:

static function getTypeRef( name:String ):Ref<ClassType>
{
    var type = Context.getType( name );

    switch( type )
    {
        default: return Context.error( "Expected a ClassType", Context.currentPos() );
        case TInst( cr, _ ):
            return cr;
    }
}


static function getTypes()
{
    // Obtain ClassType by identifier
    var fooCls = getTypeRef( "entities.Foo" );

    // Get a TypedExpr for the ClassType
    var typedExpr:TypedExpr = {
        expr : TTypeExpr( TClassDecl( fooCls ) ),
        t    : TInst( fooCls, [] ),
        pos  : Context.currentPos()
    };

    // Convert to Expr
    var expr:Expr = Context.getTypedExpr( typedExpr );

    var fields = Context.getBuildFields();

    fields.push( {
        name    : "_entities",
        access  : [Access.APublic, Access.AStatic ],
        pos     : Context.currentPos(),
        kind    : FVar( 
                    macro:Array<Class<entities.Entity>>,
                    macro $a{[ ${expr} ]}   // <- Now it works here
                  )
    });

    return fields;
}