使用TVar时如何等待M_完成？

Question

我正在编写一个函数，我使用forM_处理列表，并将结果附加到TVar列表：

import Control.Concurrent.STM
import Control.Concurrent.STM.TVar
import Control.Concurrent (forkIO)
import Control.Monad (forM_)

insert :: a -> [a] -> [a]
insert = (:) -- stub

my_func_c :: (a -> a) -> [a] -> IO [a]
my_func_c my_function arr = do

    res_var <- atomically $ newTVar ([]::[a])

    forkIO $ forM_ arr $ \x -> atomically $ do
        let y = id $! my_function x
        modifyTVar res_var (insert y)

    atomically $ readTVar res_var

如果我用-threaded编译它，结果总是为空的。 怎么可能等待线程完成？ 我不能使用MVar或Async 。 我必须使用TVar或其他基于TVar数据结构来解决这个问题

Answer 1

惯用的解决方案是使用TMVar ：

my_func_c :: (a -> a) -> [a] -> IO [a]
my_func_c my_function arr = do
    res_var <- atomically $ newTVar []
    finished <- atomically $ newEmptyTMVar

    forkIO $ do
        forM_ arr $ \x -> atomically $ do
            let y = id $! my_function x
            modifyTVar res_var (insert y)
        atomically $ putTMVar finished ()

    atomically $ takeTMVar finished >> readTVar res_var

但如果您真的只允许使用TVar ，您可以使用TVar Bool模拟TMVar () ：

my_func_c :: (a -> a) -> [a] -> IO [a]
my_func_c my_function arr = do
    res_var <- atomically $ newTVar []
    finished <- atomically $ newTVar False

    forkIO $ do
        forM_ arr $ \x -> atomically $ do
            let y = id $! my_function x
            modifyTVar res_var (insert y)
        atomically $ writeTVar finished True

    atomically $ waitTVar finished >> readTVar res_var

waitTVar :: TVar Bool -> STM ()
waitTVar tv = do
    finished <- readTVar tv
    unless finished retry

在引擎盖下， TMVar a只是一个TVar (Maybe a) （所以TMVar () ~ TVar (Maybe ()) ~ TVar Bool ）带有takeTMVar做一个readTVar和retry ，所以上面两个解决方案在操作上是完全等效的。