F＃将函数转换为使用高阶函数

Question

我有这一系列的功能， isMember ， addElem和countries ：

let rec isMember x = function
    | y::ys -> y=x || (isMember x ys)
    | []    -> false

let addElem x ys = if isMember x ys then ys else x::ys

let rec countries = function
    | []         -> []
    | (c1,c2)::m -> addElem c1 (addElem c2 (countries m))

我想用高阶函数重写国家，但我不完全确定如何：

我的猜测是它与List.map ，因为我正在将一个函数应用于列表的每个元素。

let countriesHigherOrder m = 
    List.map (fun x -> addElem x m)

Answer 1

您可以将List.fold与初始化为[]的精度一起使用，而不是使用List.map。

let countriesHigherOrder m = 
    List.fold (fun acc (c1,c2) -> addElem c1 (addElem c2 acc)) [] m

或者通过定义addPair：

let addPair (x, y) ys =
   addElem x (addElem y ys)   


let countriesHigherOrder m = 
    List.fold (fun acc (c1,c2) -> addPair (c1, c2) acc) [] m

Answer 2

如果要将对列表展平为一个简单列表，同时只保留一个相同元素，最短代码将涉及追加运算符。

let countries' m =
    List.unzip m ||> (@)
    |> Seq.distinct
    |> Seq.toList

另一方面，如果您需要双重递归方法的特殊顺序，则可以将元组列表转换为双元素列表并将它们连接起来。

let countries'' m =
    List.rev m
    |> List.collect(fun (x,y) -> [y;x])
    |> Seq.distinct
    |> Seq.toList
    |> List.rev