如何在Haxe中乘以字符串

Question

我试图将一些字符串a乘以某个整数b ，使a * b = a + a + a ...（b次） 。 我尝试过就像在python中一样：

class Test {
    static function main() {
        var a = "Text";
        var b = 4;    
        trace(a * b);    //Assumed Output: TextTextTextText
    }
}

但这引起了：

构建失败Test.hx：6：字符14-15：字符串应为Int

在Haxe Programming Cookbook或API Documentation中似乎没有任何关于乘法字符串的信息，所以我想知道我输错了什么或者我应该使用：

class Test {
    static function main() {
        var a = "Text";
        var b = 4;
        var c = ""; 

        for (i in 0...b) {
            c = c + a;
        }
        trace(c); // Outputs "TextTextTextText"
    }
}

Answer 1

数字乘法运算符*需要数字类型，如整数。 你有一个字符串。 如果要将字符串相乘，则必须通过在循环中追加目标字符串来手动执行此操作。

+运算符不是示例中的数字加号，而是组合字符串的一种方法。

你可以通过运算符重载实现你想要的：

abstract MyAbstract(String) {
    public inline function new(s:String) {
        this = s;
    }

    @:op(A * B)
    public function repeat(rhs:Int):MyAbstract {
        var s:StringBuf = new StringBuf();
        for (i in 0...rhs)
            s.add(this);
        return new MyAbstract(s.toString());
    }
}

class Main {
    static public function main() {
        var a = new MyAbstract("foo");
        trace(a * 3); // foofoofoo
    }
}

Answer 2

不是很短，但阵列理解可能在某些情况下有所帮助：

class Test {
    static function main() {
        var a = "Text";
        var b = 4;
        trace( [for (i in 0...b) a].join("") );
        //Output: TextTextTextText
    }
}

请参阅try.haxe.org 。

Answer 3

要构建tokiop的答案 ，您还可以定义times函数，然后将其用作静态扩展。

using Test.Extensions;

class Test {
    static function main() {
        trace ("Text".times(4));
    }
}

class Extensions {
    public static function times (str:String, n:Int) {
        return [for (i in 0...n) str].join("");
    }
}

在这里试试.haxe.org演示

Answer 4

要构建bsinky答案，您还可以将时间函数定义为静态扩展，但避免使用数组：

using Test.Extensions;

class Test {
    static function main() {
        trace ("Text".times(4));
    }
}

class Extensions {
    public static function times (str:String, n:Int) {
        var v = new StringBuf();
        for (i in 0...n) v.add(str);
        return v.toString();
    }
}

演示： https ： //try.haxe.org/#e5937

StringBuf可以针对不同的目标进行优化。 例如，在JavaScript目标上，它被编译为好像您只是使用字符串https://api.haxe.org/StringBuf.html

Answer 5

最快的方法（至少在https://try.haxe.org/#195A8的JavaScript目标上）似乎使用StringTools._pad 。

public static inline function stringProduct ( s : String, n : Int ) {

    if ( n < 0 ) {

        throw ( 1 );

    }

    return StringTools.lpad ( "", s, s.length * n );

}

StringTools.lpad和StringTools.rpad似乎无法决定哪个更有效。 看起来rpad对于较大的字符串可能更好，而对于较小的字符串，lpad可能更好，但是每次重新运行时它们会稍微切换一下。 haxe.format.JsonPrinter使用lpad进行连接，但我不确定要推荐哪个。