使用 catamorphism 忘记 Cofree 注释

Question

我有一个 AST，我正在使用Cofree注释：

data ExprF a
  = Const Int
  | Add a
        a
  | Mul a
        a
  deriving (Show, Eq, Functor)

我使用type Expr = Fix ExprF来表示未标记的 AST，并使用type AnnExpr a = Cofree ExprF a来表示标记的。 我已经找到了一个函数，通过丢弃所有注释将标记的 AST 转换为未标记的 AST：

forget :: Functor f => Cofree f a -> Fix f
forget = Fix . fmap uncofree . unwrap

这看起来可能是某种变形（我使用的是 Kmett 的recursion-schemes包中的定义）。

cata :: (Base t a -> a) -> t -> a
cata f = c where c = f . fmap c . project

我认为上面使用 catamorphism 重写的内容看起来像这样，但我无法弄清楚为alg放置什么来使其类型检查。

forget :: Functor f => Cofree f a -> Fix f
forget = cata alg where
  alg = ???

任何帮助确定这是否真的是 cata/anamorphism，以及为什么它是/不是的一些直觉将不胜感激。

Answer 1

forget :: Functor f => Cofree f a -> Fix f
forget = cata (\(_ :< z) -> Fix z)
-- (Control.Comonad.Trans.Cofree.:<)
-- not to be confused with
-- (Control.Comonad.Cofree.:<)

解释

只看类型，我们可以证明实际上只有一种方法可以实现forget 。 让我们从cata的类型开始：

cata :: Recursive t => (Base t b -> b) -> t -> b

这里t ~ Cofree fa和Base for Cofree的类型实例给出：

type instance Base (Cofree f a) = CofreeF f a

CofreeF在哪里：

data CoFreeF f a b = a :< f b
-- N.B.: CoFree also defines a (:<) constructor so you have to be
-- careful with imports.

即，花哨的配对类型。 让我们用实际的配对类型替换它，以使事情更清楚：

cata :: Functor f => ((a, f b) -> b) -> Cofree f a -> b

现在我们真的专门用一个更具体的b专门化cata ，即Fix f ：

-- expected type of `cata` in `forget`
cata :: Functor f => ((a, f (Fix f)) -> Fix f) -> Cofree f a -> Fix f

forget在a和f是参数化的，所以我们给cata的函数不能对a对中的a做任何事情，实现剩余f (Fix f) -> Fix f的唯一明智方法是Fix包装器。

操作上， Fix是恒等式，所以(\\(_ :< z) -> Fix z)真的是(\\(_ :< z) -> z)这对应于去除注解的直觉，即第一个组件对(_ :< z) 。