反转SPARQL中的字符串

Question

是否可以在SPARQL中反转字符串，例如，“ abc”变为“ cba”。 可替代地，可以基于相反的字符串排序。

我对在Wikidata Query Service上可以使用的解决方案特别感兴趣。

Answer 1

好吧，您问是否有可能 ，而不是是否可行 ...

SELECT ?s (group_concat(?letter; separator='') AS ?r) {
  BIND ("abcdefghijkl" AS ?s)
  VALUES ?d1 { 0 1 2 3 4 5 6 7 8 9 }
  VALUES ?d2 { 0 1 2 3 4 5 6 7 8 9 }
  VALUES ?d3 { 0 1 2 3 4 5 6 7 8 9 }
  BIND (100 * ?d3 + 10 * ?d2 + ?d1 + 1 AS ?i)
  BIND (SUBSTR(?s, ?i, 1) AS ?letter)
}
GROUP BY ?s

实时链接

该方法与Finn的响应中的方法类似，但适用于长度不超过1000个字符的字符串。 这将用作较大查询中的子查询。 诸如group_concat聚合不保证特定顺序，因此此查询依赖于Blazegraph使用的与实现相关的顺序，并且可能使字符串在其他实现上混乱。

如果用例按相反的顺序按字符串的最后一个字符排序，则可以对其进行调整，以确保包括字符串的最后n个字符。

Answer 2

SPARQL 1.1中没有“反向字符串”功能。

没有提供要查找的ORDER BY修饰符 。

许多（如果不是大多数的话）编程和脚本语言确实具有“反向字符串”和“排序”方法，因此我建议调查您（未命名）的开发环境是否具有这种方法。

Answer 3

这种病理实现显然在Blazegraph / Wikidata查询服务中有效（最多达到特定的字符串长度，此处为12）：

SELECT ?s ?r {
  BIND("abcdefghijkl" AS ?s)
  BIND(CONCAT(SUBSTR(?s, 12, 1), SUBSTR(?s, 11, 1), SUBSTR(?s, 10, 1),
              SUBSTR(?s, 9, 1), SUBSTR(?s, 8, 1), SUBSTR(?s, 7, 1),
              SUBSTR(?s, 6, 1), SUBSTR(?s, 5, 1), SUBSTR(?s, 4, 1),
              SUBSTR(?s, 3, 1), SUBSTR(?s, 2, 1), SUBSTR(?s, 1, 1)) AS ?r)
}

Answer 4

这是一个针对Virtuoso的查询，通过子查询提供了所需的解决方案。

SELECT ?str (GROUP_CONCAT(?letter; separator="") AS ?reverse)
WHERE {
          {
              SELECT ?str ?charAt 
              WHERE {
                      VALUES ?str { "abcdefghijk" }
                      VALUES ?d1 { 0 1 2 3 4 5 6 7 8 9 10 }
                      BIND(STRLEN(?str) - ?d1 AS ?charAt)
                      FILTER(?charAt > 0)
                    }
           }

          BIND(SUBSTR(?str,?charAt,1) AS ?letter) 
     }

实时查询结果页面 。