使用 Excel VBA 进行字符串到日期转换

Question

有一个字符串日期时间，其中包含需要删除的待处理“AEST”，以便进行日期计算

使用“查找和替换”空白作品手动执行此操作。 但是想在 VBA 中这样做是行不通的。 - 例如，当有 4 个样本日期时存在不一致，其中 2 个日期被转换为美国时间而不是澳大利亚时间。 - 不知道这种不一致的根本原因

Sub KPIM_RptMth()

Range("H:H").Select
Selection.Replace What:="AEST", Replacement:="", LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False

End Sub

e.g. sample dates:

[REQ] WOC Date and Time
12-04-2019 01:03:32 PM AEST
22-06-2019 08:33:04 AM AEST
11-06-2019 03:30:00 PM AEST
17-06-2019 02:50:00 PM AEST

the correct output is:

[REQ] WOC Date and Time
12/04/2019 13:03
22/06/2019 8:33
11/06/2019 15:30
17/06/2019 14:50

the actual output after the VBA script above runs is:
[REQ] WOC Date and Time
4/12/2019 13:03
22-06-2019 08:33:04 AM 
6/11/2019 15:30
17-06-2019 02:50:00 PM 

Answer 1

问题是计算机无法知道该字符串日期的格式

12-04-2019 01:03:32 PM AEST

可能是以下两种

dd-mm-yyyy
mm-dd-yyyy

所以你所做的就是让计算机猜测并且它失败了。 即使是人类也无法说出这两种格式中的哪一种是正确的。 因此，作为字符串且没有实际日期的日期是毫无用处的（除非您有关于格式的其他信息，这不是日期字符串本身的一部分）。

因此，将字符串转换为日期的唯一可行解决方案是，如果您知道这两种格式中的哪一种是正确的，则使用此信息将日期拆分为多个片段并使用DateSerial function从中创建一个真实的日期.

您需要对每个单元格执行如下操作作为字符串日期转换。

一个例子

Public Sub ConvertTimeStampToRealDateTime()
    Dim TimeStampString As String
    TimeStampString = "12-04-2019 01:03:32 PM AEST"

    'split by spaces
    Dim SplitTimeStamp As Variant
    SplitTimeStamp = Split(TimeStampString, " ")
        'SplitTimeStamp(0) = "12-04-2019"
        'SplitTimeStamp(1) = "01:03:32"
        'SplitTimeStamp(2) = "PM"
        'SplitTimeStamp(3) = "AEST"

    'split date by dash
    Dim SplitDate As Variant
    SplitDate = Split(SplitTimeStamp(0), "-")
        'SplitDate(0) = "12"
        'SplitDate(1) = "04"
        'SplitDate(2) = "2019"

    'now we add the information which of the 3 split parts is day, month and year
    'and put it together to a real date
    Dim RealDate As Date
    RealDate = DateSerial(SplitDate(2), SplitDate(1), SplitDate(0))

    'cast time string into a date
    Dim RealTime As Date
    RealTime = SplitTimeStamp(1) & " " & SplitTimeStamp(2)
        'casting from string to date works good for times but not for dates
        'so we can do that with the time

    'Add date and time to make it a datetime
    Dim RealDateTime As Date
    RealDateTime = RealDate + RealTime 'note that we need to ADD them mathematically (+) this is not a string concatenation (&)!!!

    'AEST: This information about how many hours you need to add or subtract
    '      from this datetime to convert it into your desired time zone needs
    '      needs to be done manually

    Dim RealDateTimeInMyZone As Date
    RealDateTimeInMyZone = DateAdd("h", -3, RealDateTime) 'for example subtract 3 hours
End Sub

最后，您可以将实际日期时间写入单元格并使用Range("A1").NumberFormat将其格式化为您喜欢的格式。

^{图 1：字符串到日期转换期间的变量值。}

请注意，上面的代码只是这个概念的一个例子。 如果您需要使其稳固，您可能需要进行一些检查和错误处理，因为它会因意外输入字符串而失败。

此外，用它制作 function 可能是个好主意，您可以像这样重复使用：

Public Function ConvertDDMMYYYYTimeStampToRealDateTime(ByVal TimeStampString As String) As Date

End Function

Answer 2

您也可以使用 Excel 2010+ 中提供的Power Query aka Get & Transform

所有步骤都可以通过 GUI 完成

• 从表/范围中获取数据
• 按space分隔符拆分列（仅限最右边的实例）
• 更改格式——通过语言环境选择DateTime时间作为格式，选择English(Australia)作为语言环境

完成此操作一次后，如果刷新数据源表，则可以更新查询。

工作表现在将包含“真实的” Excel 日期/时间，如果未按您希望的方式格式化，只需更改单元格格式。

原来的

结果

M-Code （您实际上并不需要它，但如果您将其粘贴到高级编辑器中，如果您遇到问题，它将重新创建 GUI 步骤。

如果您使用此方法，您可能需要更改Table名称。 )

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Split Column by Delimiter" = Table.SplitColumn(Source, "[REQ] WOC Date and Time", Splitter.SplitTextByEachDelimiter({" "}, QuoteStyle.Csv, true), {"[REQ] WOC Date and Time.1", "[REQ] WOC Date and Time.2"}),
    #"Removed Columns" = Table.RemoveColumns(#"Split Column by Delimiter",{"[REQ] WOC Date and Time.2"}),
    #"Changed Type with Locale" = Table.TransformColumnTypes(#"Removed Columns", {{"[REQ] WOC Date and Time.1", type datetime}}, "en-AU")
in
    #"Changed Type with Locale"