Oracle 如何使用循环动态更改函数中的参数/参数

Question

如何使用循环动态更改管道函数中的参数/参数？ 这是示例。

CREATE OR REPLACE FUNCTION TESTES(
P_VALUE1 VARCHAR2,
P_VALUE2 VARCHAR2,
P_VALUE3  VARCHAR2 
)RETURN VARCHAR2

PIPELINED
AS
L_DYNM VARCHAR2(1000);
L_QUERY VARCHAR2(1000);
L_RETURN VARCHAR2(1000);

BEGIN
FOR i IN 1..3 LOOP
    L_DYNM := 'P_VALUE' || i || ',';
END LOOP;

L_QUERY := 'SELECT' || L_DYNM ||'FROM DUAL';


/* SELECT SME_PACE.SYS_REGEX_DEBIT(P_VALUE) INTO L_RETURN FROM DUAL; */
FOR V_REC IN (
    EXECUTE IMMEDIATE L_QUERY
        INTO L_RETURN
)
LOOP
    PIPE ROW (
        OBJECT_TESTES(
            V_REC.FIELD1, V_REC.FIELD2, V_REC.FIELD3
    );
END LOOP;
END;

所以我实际上想要尝试做的是从双动态运行SELECT P_VALUE1, P_VALUE2, P_VALUE3并在管道行上使用它。

我必须这样做是有原因的，我需要一个答案是否可以这样做？ 所以我可以将它应用到我的项目中。

谢谢

Answer 1

您的功能有很多不一致之处：

• 返回类型是VARCHAR2但您正在尝试使用将返回集合的PIPELINE 。
• 您将在循环的每次迭代中覆盖L_DYNM的值。
• 当DUAL表只有一个DUMMY列时，您正试图从DUAL表中选择三个动态列名。

然后你有语法错误：

• 无与伦比的右括号。
• 在FOR语句中EXECUTE IMMEDIATE 。

你可能想要这样的东西：

CREATE TYPE object_testes IS OBJECT(
  a VARCHAR2(100),
  b VARCHAR2(100),
  c VARCHAR2(100)
);

CREATE TYPE object_testes_table IS TABLE OF object_testes;

CREATE OR REPLACE FUNCTION TESTES(
  P_VALUE1 VARCHAR2,
  P_VALUE2 VARCHAR2,
  P_VALUE3  VARCHAR2 
) RETURN object_testes_table PIPELINED
AS
  p_cur SYS_REFCURSOR;
  p_sql VARCHAR2(4000);
  p_field1 VARCHAR2(100);
  p_field2 VARCHAR2(100);
  p_field3 VARCHAR2(100);
BEGIN
  p_sql := 'SELECT ' || DBMS_ASSERT.ENQUOTE_NAME( p_value1 ) || ', '
                     || DBMS_ASSERT.ENQUOTE_NAME( p_value2 ) || ', '
                     || DBMS_ASSERT.ENQUOTE_NAME( p_value3 ) || ' '
           || 'FROM DUAL';

  OPEN p_cur FOR p_sql;

  LOOP
    FETCH p_cur INTO p_field1, p_field2, p_field3;
    EXIT WHEN p_cur%NOTFOUND;
    PIPE ROW (
      OBJECT_TESTES(
        p_field1,
        p_field2,
        p_field3
      )
    );
  END LOOP;

  CLOSE p_cur;
END;
/

然后：

SELECT * FROM TABLE( testes( 'DUMMY', 'DUMMY', 'DUMMY' ));

输出：

\n一个 | 乙 |  C \n :- |  :- |  :-\n X |  X |  X \n

db<> 在这里摆弄

Answer 2

试试下面的方法。 这将做同样的事情，但不使用select P_Value1 dual 。

创建对象：

CREATE TYPE sample_record AS OBJECT (P_VALUE1 VARCHAR2(10),
P_VALUE2  VARCHAR2(10),
P_VALUE3  VARCHAR2(10)
);/

然后创建创建对象的数组。

CREATE TYPE sample_records IS TABLE OF sample_record; /

将对象转换为管道行的函数：

CREATE OR REPLACE FUNCTION test (P_VALUE1 VARCHAR2,P_VALUE2 VARCHAR2,P_VALUE3  VARCHAR2) 
RETURN sample_records PIPELINED AS
     BEGIN
               PIPE ROW(sample_record(P_VALUE1,P_VALUE2,P_VALUE3));    
     RETURN;
END;
/

然后按照下面的方式调用上面的函数。 您也可以在循环中调用它：

select * from table(test('A','B','C'));