Terraform 在 zip 准备好之前创建 lambda

Question

我正在尝试创建一个 Terraform 模块来构建我的 JS lambdas，zip 并部署它们。 然而，这被证明是有问题的

resource "null_resource" "build_lambda" {
  count = length(var.lambdas)

  provisioner "local-exec" {
    command = "mkdir tmp"
    working_dir = path.root
  }

  provisioner "local-exec" {
    command = var.lambdas[count.index].code.build_command
    working_dir = var.lambdas[count.index].code.working_dir
  }
}

data "archive_file" "lambda_zip" {
  count = length(var.lambdas)
  type        = "zip"
  source_dir = var.lambdas[count.index].code.working_dir
  output_path = "${path.root}/tmp/${count.index}.zip"

  depends_on = [
    null_resource.build_lambda
  ]
}

/*******************************************************
* Lambda definition
*******************************************************/
resource "aws_lambda_function" "lambda" {
  count = length(var.lambdas)
  filename = data.archive_file.lambda_zip[count.index].output_path
  source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)
  function_name = "${var.application_name}-${var.lambdas[count.index].name}"
  description = var.lambdas[count.index].description

  handler = var.lambdas[count.index].handler
  runtime = var.lambdas[count.index].runtime
  role = aws_iam_role.iam_for_lambda.arn
  memory_size = var.lambdas[count.index].memory_size

  depends_on = [aws_iam_role_policy_attachment.lambda_logs, aws_cloudwatch_log_group.log_group, data.archive_file.lambda_zip]
}

属性source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)虽然在技术上不是强制性的，但它是必要的，否则现有的 lambda 将永远不会被覆盖，因为 Terraform 会认为它仍然是 lambda 的相同版本并且将完全跳过部署。 不幸的是，它看起来像方法 filebase64sha256 在创建任何资源之前被评估。 这意味着 hash 计算没有 zip，所以我得到错误

Error: Error in function call

  on modules\api-gateway-lambda\main.tf line 35, in resource "aws_lambda_function" "lambda":
  35:   source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)
    |----------------
    | count.index is 0
    | data.archive_file.lambda_zip is tuple with 1 element

Call to function "filebase64sha256" failed: no file exists at tmp\0.zip.

如果我手动将 zip 放在正确的位置，我可以看到整个事情开始工作，zip 最终被一个新的覆盖，但在这种情况下 hash 必须来自以前的 zip。正确的方法是什么以正确的顺序执行整个事情？

Answer 1

archive_file数据源有它自己的output_base64sha256属性，它可以给你相同的结果，而无需要求 Terraform 读取尚不存在的文件：

  source_code_hash = data.archive_file.lambda_zip[count.index].output_base64sha256

数据源将在创建文件的同时填充它，并且由于您的 lambda function 取决于数据源，因此在评估 lambda function 配置之前它始终可用。