如何有选择地调用此 APOC 程序？ （仅在节点的子集上）

Question

我有一个 Neo4J 数据库，其中包含许多 label com 节点。 这些节点包含一个关键属性——它以我想要的方式对它们进行唯一分组。 它们还具有时间戳属性，以及许多其他 integer 属性。

这是我面临的问题：我想使用 APOC 图分组过程根据它们的关键属性将这些节点聚合在一起。 但是，我想有选择地这样做——这样我只聚合节点，如果它们的时间戳属性满足提供的时间 window。

我试图根据时间戳使用 WHERE 子句匹配和过滤节点，但我无法将这些节点专门传递给nodes.group过程。 基本上，我需要弄清楚如何只在特定的节点子集上调用nodes.group 。 我会很感激任何帮助。

这是我正在执行的呼叫：

CALL apoc.nodes.group(['com'], ['key'], [{val1: 'sum', val2: 'sum', val3: 'sum',' time_start: 'collect'}]) YIELD node

正如我上面提到的，我尝试执行

MATCH (c:com) WHERE c.time_start >= datetime('2020-12-16T21:45:05Z')

...在程序之前，然后链接查询，但它不起作用。

该过程仍然在 com 关系的所有节点上调用，而不仅仅是我过滤的那些节点。

Answer 1

该过程本身不允许您通过此类过滤器。 然而，有两种可能性可以规避这一点：

1. 使用 vNode 和 vRelationship 自己构建虚拟图
2. 在您的节点选择和分组之后设置一个临时 label

我将专注于选项2：

以下图为例：

UNWIND range(1, 200) AS i
CREATE (n:com)
SET n.timestamp = i, 
n.key = apoc.coll.randomItem(items)

假设我有一个假设的 window 使用，即30 to 70 ，我只能找到与我的 window 谓词匹配的节点：

WITH [30, 70] AS window
MATCH (n:com) 
WHERE n.timestamp > window[0] 
AND n.timestamp < window[1]
RETURN count(n)

╒══════════╕
│"count(n)"│
╞══════════╡
│39        │
└──────────┘

在进入分组查询之前，我只想说明您可以设置一个 label 并在同一个查询中使用谓词将其删除。

WITH [30, 70] AS window
MATCH (n:com) 
WHERE n.timestamp > window[0] 
AND n.timestamp < window[1]
SET n:temporary
WITH count(n) AS doSomething
MATCH (n:temporary)
REMOVE n:temporary
WITH count(*) AS break, doSomething
RETURN doSomething

最后一个WITH count(*)是每个临时节点不返回一行所必需的。

现在，使用这个逻辑，我们可以：

1. 使用 window 谓词的MATCH节点
2. 为他们分配一个新的temporary label
3. 在temporary label 上使用apoc.nodes.group
4. 卸下temporary label
5. 返回分组的节点

WITH [30, 70] AS window
MATCH (n:com) WHERE n.timestamp > window[0] AND n.timestamp < window[1]
SET n:temporary
WITH window, count(*) AS x
CALL apoc.nodes.group(['temporary'], ['key'], null, {})
YIELD node, relationship
WITH collect(node) AS elements
MATCH (n:temporary) REMOVE n:temporary
WITH count(*) AS break, elements
UNWIND elements AS element
RETURN element

╒════════════════════════╕
│"element"               │
╞════════════════════════╡
│{"count_*":6,"key":"f"} │
├────────────────────────┤
│{"count_*":6,"key":"e"} │
├────────────────────────┤
│{"count_*":12,"key":"d"}│
├────────────────────────┤
│{"count_*":1,"key":"c"} │
├────────────────────────┤
│{"count_*":5,"key":"b"} │
├────────────────────────┤
│{"count_*":9,"key":"a"} │
└────────────────────────┘