根据模式匹配行并重新格式化文件 Bash/ Linux

Question

我正在寻找解决以下问题的 bash/Linux 方法。

我有一个看起来像这样的文本文件（ input.txt ）（还有更多行）：

TCCTCCGC+TAGTTAGG_Vel_24_CC_LlanR_34    CC_LlanR
GGAGTATG+TCTATTCG_Vel_24_CC_LlanR_22    CC_LlanR
TTGACTAG+TGGAGTAC_Vel_02_EN_DavaW_11    EN_DavaW
TCGAATAA+TGGTAATT_Vel_24_CC_LlanR_23    CC_LlanR
CTGCTGAA+CGTTGCGG_Vel_02_EN_DavaW_06    EN_DavaW
index_07_barcode_04_PA-17-ACW-04        17-ACW
index_09_barcode_05_PA-17-ACW-05        17-ACW
index_08_barcode_37_PA-21-YC-15         21-YC
index_09_barcode_04_PA-22-GB-10         22-GB
index_10_barcode_37_PA-28-CC-17         28-CC
index_11_barcode_29_PA-32-MW-07         32-MW
index_11_barcode_20_PA-32-MW-08         32-MW

我想生成一个看起来像的文件

CC_LlanR(TCCTCCGC+TAGTTAGG_Vel_24_CC_LlanR_34,GGAGTATG+TCTATTCG_Vel_24_CC_LlanR_22,TCGAATAA+TGGTAATT_Vel_24_CC_LlanR_23)
EN_DavaW(TTGACTAG+TGGAGTAC_Vel_02_EN_DavaW_11,CTGCTGAA+CGTTGCGG_Vel_02_EN_DavaW_06)
17-ACW(index_07_barcode_04_PA-17-ACW-04,index_09_barcode_05_PA-17-ACW-05)
21-YC(index_08_barcode_37_PA-21-YC-15)
22-GB(index_09_barcode_04_PA-22-GB-10)
28-CC(index_10_barcode_37_PA-28-CC-17)
32-MW(index_11_barcode_29_PA-32-MW-07,index_11_barcode_20_PA-32-MW-08)

我想我可以按照这个思路做点什么。

cat input.txt | awk '{print $1}' | grep -e "CC_LlanR" | paste -sd',' > intermediate_file
cat input.txt | awk '{print $2"("}' something something??

但我只知道如何 grep 一次一个模式？ 有没有办法一次找到所有匹配的行和 output 以这种格式？

谢谢！ （祝大家复活节快乐/长周末！）

Answer 1

使用您显示的示例，请尝试以下操作。

awk '
FNR==NR{
  arr[$2]=(arr[$2]?arr[$2]",":"")$1
  next
}
($2 in arr){
  print $2"("arr[$2]")"
  delete arr[$2]
}
' Input_file Input_file

第二种解决方案：在 Input_file 的单次读取中尝试以下操作。

awk '{arr[$2]=(arr[$2]?arr[$2]",":"")$1} END{for(i in arr){print i"("arr[i]")"}}' Input_file

说明（第一种解决方案）：在此处添加第一种解决方案的详细说明。

awk '                      ##Starting awk program from here.
FNR==NR{                   ##Checking condition FNR==NR which will be TRUE when first time Input_file is being read.
  arr[$2]=(arr[$2]?arr[$2]",":"")$1 ##Creating array with index of 2nd field and keep adding its value with comma here.
  next                     ##next will skip all further statements from here.
}
($2 in arr){               ##Checking condition if 2nd field is present in arr then do following.
  print $2"("arr[$2]")"    ##Printing 2nd field ( arr[$2] ) here.
  delete arr[$2]           ##Deleteing arr value with 2nd field index here.
}
' Input_file Input_file    ##Mentioning Input_file names here.

Answer 2

假设您的输入按示例中所示的$2值分组（如果不是，则首先在您的输入上运行sort -k2,2 ），使用 1 遍并且一次仅在 memory 中存储一个令牌并生成 output与输入相同的$2顺序：

$ cat tst.awk
BEGIN { ORS="" }
$2 != prev {
    printf "%s%s(", ORS, $2
    ORS = ")\n"
    sep = ""
    prev = $2
}
{
    printf "%s%s", sep, $1
    sep = ","
}
END { print "" }

$ awk -f tst.awk input.txt
CC_LlanR(TCCTCCGC+TAGTTAGG_Vel_24_CC_LlanR_34,GGAGTATG+TCTATTCG_Vel_24_CC_LlanR_22)
EN_DavaW(TTGACTAG+TGGAGTAC_Vel_02_EN_DavaW_11)
CC_LlanR(TCGAATAA+TGGTAATT_Vel_24_CC_LlanR_23)
EN_DavaW(CTGCTGAA+CGTTGCGG_Vel_02_EN_DavaW_06)
17-ACW(index_07_barcode_04_PA-17-ACW-04,index_09_barcode_05_PA-17-ACW-05)
21-YC(index_08_barcode_37_PA-21-YC-15)
22-GB(index_09_barcode_04_PA-22-GB-10)
28-CC(index_10_barcode_37_PA-28-CC-17)
32-MW(index_11_barcode_29_PA-32-MW-07,index_11_barcode_20_PA-32-MW-08)

Answer 3

这可能对您有用（GNU sed）：

sed -E 's/^(\S+)\s+(\S+)/\2(\1)/;H
        x;s/(\n\S+)\((\S+)\)(.*)\1\((\S+)\)/\1(\2,\4)\3/;x;$!d;x;s/.//' file

Append 每条操纵线到保持空间。

在继续下一行之前，将类似的键累积到一行中。

删除除最后一行之外的每一行。

用保留空间的内容替换最后一行。

删除第一个字符（由H命令引入的换行符）并打印结果。

NB 最终的解决方案是未排序的并且按照原始顺序。