Perl 如何使用另一个 hash 的密钥从 hash 获取值

Question

我有两个 hash，第一个 %hash 包含唯一键和值。

另一个 %channel 仅包含已作为 %hash 值存在的商店

我想显示引用商店（例如 Store::CAR）的所有类别 ID （例如 Category::1375567 等）

在我需要的预期结果之下，它将比我的解释更有效。

my %hash = (
        'Category::1375567' => 'Store::CAR|Category::1375567|CAR Concert',
        'Category::1299556' => 'Store::CHANNEL|Category::1299556|Culture',
        'Category::1314571' => 'Store::TV|Category::1314571|Emissions',
        'Category::1375568' => 'Store::CAR|Category::1375568|Sciences',
        'Category::1314570' => 'Store::TV|Category::1314570|Info',
        'Category::1314572' => 'Store::TV|Category::1314572|Jeunesse',
        'Category::1314569' => 'Store::TV|Category::1314569|Séries & Fictions',
        'Category::1294556' => 'Store::CHANNEL|Category::1294556|Documentaire',
        'Category::1326557' => 'Store::CHANNEL|Category::1326557|Sport'
);

my %channel = (
        'Store::TV' => 'Store::TV',
        'Store::CAR' => 'Store::CAR',
        'Store::CHANNEL' => 'Store::CHANNEL'
);

预期结果

    Store::CAR
Store::CAR|Category::1375567|CAR Concert
Store::CAR|Category::1375568|Sciences

    Store::CHANNEL
Store::CHANNEL|Category::1294556|Documentaire
Store::CHANNEL|Category::1299556|Culture
Store::CHANNEL|Category::1326557|Sport

    Store::TV
Store::TV|Category::1314569|Séries & Fictions
Store::TV|Category::1314570|Info
Store::TV|Category::1314571|Emissions
Store::TV|Category::1314572|Jeunesse

实际结果

    Store::CAR
Store::CAR|Category::1375567|CAR Concert
Store::CAR|Category::1375568|Sciences
Store::CHANNEL|Category::1294556|Documentaire
Store::CHANNEL|Category::1299556|Culture
Store::CHANNEL|Category::1326557|Sport
Store::TV|Category::1314569|Séries & Fictions
Store::TV|Category::1314570|Info
Store::TV|Category::1314571|Emissions
Store::TV|Category::1314572|Jeunesse

    Store::CHANNEL
Store::CAR|Category::1375567|CAR Concert
Store::CAR|Category::1375568|Sciences
Store::CHANNEL|Category::1294556|Documentaire
Store::CHANNEL|Category::1299556|Culture
Store::CHANNEL|Category::1326557|Sport
Store::TV|Category::1314569|Séries & Fictions
Store::TV|Category::1314570|Info
Store::TV|Category::1314571|Emissions
Store::TV|Category::1314572|Jeunesse

这是我到目前为止所做的

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;
use feature 'say';

my %hash = (
        'Category::1375567' => 'Store::CAR|Category::1375567|CAR Concert',
        'Category::1299556' => 'Store::CHANNEL|Category::1299556|Culture',
        'Category::1314571' => 'Store::TV|Category::1314571|Emissions',
        'Category::1375568' => 'Store::CAR|Category::1375568|Sciences',
        'Category::1314570' => 'Store::TV|Category::1314570|Info',
        'Category::1314572' => 'Store::TV|Category::1314572|Jeunesse',
        'Category::1314569' => 'Store::TV|Category::1314569|Séries & Fictions',
        'Category::1294556' => 'Store::CHANNEL|Category::1294556|Documentaire',
        'Category::1326557' => 'Store::CHANNEL|Category::1326557|Sport'
);


my %channel = (
        'Store::TV' => 'Store::TV',
        'Store::CAR' => 'Store::CAR',
        'Store::CHANNEL' => 'Store::CHANNEL'
);

if (%channel) {
        foreach (sort keys %channel) {
                say "\t", $_;
                my @tab = grep{/'$_'/} sort values %hash;
                if (@tab) {
                        foreach my $line (@tab) {
                                say $line;
                        }
                        say "";
                }
        }
}

#say Dumper(\%hash, \%channel);

__END__

Answer 1

您可以删除一些冗余以使散列更小。

另外，添加utf8因为脚本包含字符é ； 要正确打印，请添加open 。

转换第一个 hash 以便您通过公共值键入值。 由于每个转换后的键有多个值，因此请使用 arrays 的 hash。

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use utf8;
use open OUT => ':encoding(UTF-8)', ':std';

my %hash = (
        '1375567' => 'Store::CAR|CAR Concert',
        '1299556' => 'Store::CHANNEL|Culture',
        '1314571' => 'Store::TV|Emissions',
        '1375568' => 'Store::CAR|Sciences',
        '1314570' => 'Store::TV|Info',
        '1314572' => 'Store::TV|Jeunesse',
        '1314569' => 'Store::TV|Séries & Fictions',
        '1294556' => 'Store::CHANNEL|Documentaire',
        '1326557' => 'Store::CHANNEL|Sport'
);

my %channel;
@channel{qw{ Store::TV Store::CAR Store::CHANNEL }} = ();

my %transformed;
for my $category (keys %hash) {
    my ($val1, $val2) = split /\|/, $hash{$category};
    push @{ $transformed{$val1} }, [$category, $val2];
}

for my $ch (sort keys %channel) {
    say ' ' x 4, $ch;
    local $" = '|';
    say "Category::@$_" for sort { $a->[0] <=> $b->[0] } @{ $transformed{$ch} };
    say "";
}

Answer 2

以下演示代码使用$stores创建新的 hash 引用，其中键是store id ，值从%hash复制。

使用来自 hash 的密钥%channel output 数据来自 hash 参考与$stores

#!/usr/bin/env perl

use strict;
use warnings;
use feature 'say';

use utf8;

my $stores;
my %hash = (
        'Category::1375567' => 'Store::CAR|Category::1375567|CAR Concert',
        'Category::1299556' => 'Store::CHANNEL|Category::1299556|Culture',
        'Category::1314571' => 'Store::TV|Category::1314571|Emissions',
        'Category::1375568' => 'Store::CAR|Category::1375568|Sciences',
        'Category::1314570' => 'Store::TV|Category::1314570|Info',
        'Category::1314572' => 'Store::TV|Category::1314572|Jeunesse',
        'Category::1314569' => 'Store::TV|Category::1314569|Séries & Fictions',
        'Category::1294556' => 'Store::CHANNEL|Category::1294556|Documentaire',
        'Category::1326557' => 'Store::CHANNEL|Category::1326557|Sport'
);

my %channel = (
        'Store::TV' => 'Store::TV',
        'Store::CAR' => 'Store::CAR',
        'Store::CHANNEL' => 'Store::CHANNEL'
);

for ( values %hash ) {
        my($id,$cat,$desc) = split /\|/;
        push @{$stores->{$id}}, $_;
}

for my $id ( sort keys %channel ) {
        say ' ' x 4 . $id;
        say $_ for @{$stores->{$id}};
        say '';
}

exit 0;

Output

    Store::CAR
Store::CAR|Category::1375567|CAR Concert
Store::CAR|Category::1375568|Sciences

    Store::CHANNEL
Store::CHANNEL|Category::1294556|Documentaire
Store::CHANNEL|Category::1299556|Culture
Store::CHANNEL|Category::1326557|Sport

    Store::TV
Store::TV|Category::1314569|Séries & Fictions
Store::TV|Category::1314570|Info
Store::TV|Category::1314571|Emissions
Store::TV|Category::1314572|Jeunesse