我们在Perl中有autochomp吗？

Question

这是我的Perl代码用于监视Unix文件夹的样子：

#!/usr/bin/perl
use strict;
use warnings;
use File::Spec::Functions;

my $date    = `date`; chomp $date;
my $datef   = `date +%Y%m%d%H%M.%S`; chomp $datef;
my $pwd     = `pwd`; chomp $pwd;

my $cache   = catfile($pwd, "cache");
my $monitor = catfile($pwd, "monme");
my $subject = '...';
my $msg     = "...";
my $sendto  = '...';
my $owner   = '...';

sub touchandmail {
     `touch $cache -t "$datef"`;
     `echo "$msg" | mail -s "$subject" $owner -c $sendto`;
}

while(1) {

    $date  = `date`; chomp $date;
    $datef = `date +%Y%m%d%H%M.%S`; chomp $datef; 

    if (! -e "$cache") {
        touchandmail();
    } elsif ("`find $monitor -newer $cache`" ne "") {
        touchandmail();
    }
    sleep 300;
}

• 在每次任务后做一个chomp看起来不太好。 有没有办法做“autochomp”？

• 我是Perl的新手，可能没有以最好的方式编写这段代码。 欢迎任何改进代码的建议。

Answer 1

那么不要使用shell。

#! /usr/bin/perl

use warnings;
use strict;

use Cwd;
use POSIX qw/ strftime /;

my $date    = localtime;
my $datef   = strftime "%Y%m%d%H%M.%S", localtime;
my $pwd     = getcwd;

结果略有不同： date命令的输出包含一个时区，但上面$date的值不会。 如果这是一个问题，请遵循Chas的优秀建议。 Owens下面并使用strftime来获得你想要的格式。

你的分

sub touchandmail {
  `touch $cache -t "$datef"`;
  `echo "$msg" | mail -s "$subject" $owner -c $sendto`;
}

如果出现问题，将无声地失败。 沉默的失败是令人讨厌的。 更好的是代码

sub touchandmail {
  system("touch", "-t", $datef, $cache) == 0
    or die "$0: touch exited " . ($? >> 8);

  open my $fh, "|-", "mail", "-s", $subject, $owner, "-c", $sendto
    or die "$0: could not start mail: $!";

  print $fh $msg
    or warn "$0: print: $!";

  unless (close $fh) {
    if ($! == 0) {
      die "$0: mail exited " . ($? >> 8);
    }
    else {
      die "$0: close: $!";
    }
  }
}

使用system而不是反引号更能表达你的意图，因为反引号用于捕获输出。 system(LIST)形式绕过shell并且不得不担心引用参数。

获得shell管道echo ... | mail ...的效果echo ... | mail ... echo ... | mail ...没有shell意味着我们必须自己做一些管道工作，但是system(LIST)的好处 - 不必担心shell引用。 上面的代码使用了多参数open ：

对于三个或更多参数，如果MODE为'|-' ，则文件名被解释为输出要输出的命令，如果MODE为'-|' ，文件名被解释为管道输出给我们的命令。 在双参数（和单参数）形式中，应该用命令替换破折号（ '-' ）。 有关此问题的更多示例，请参阅在perlipc中使用open for IPC 。

上面的open了一个mail进程， $fh连接到它的标准输入。 父进程（仍然运行touchandmail的代码）使用print $fh $msg执行echo的角色。 由于我们打开它的方式，调用close刷新句柄的I / O缓冲区以及一些额外的内容：

如果文件句柄来自管道open ，则如果其中一个其他系统调用失败或者其程序以非零状态退出，则close返回false。 如果唯一的问题是程序退出非零， $! 将被设置为0.关闭管道还等待管道上执行的进程退出 - 如果您希望之后查看管道的输出 - 并隐式将该命令的退出状态值放入$? 和${^CHILD_ERROR_NATIVE} 。

Answer 2

更一般地说， IO::All模块确实提供了相当于autochomp的功能：

use IO::All;
# for getting command output:
my @date = io("date|")->chomp->slurp;
#$date[0] contains the chomped first line of the output

或更一般地说：

my $fh = io("file")->chomp->tie;
while (<$fh>) {
 # no need to chomp here !  $_ is pre-chomped
}

当然，对于这个date特殊情况，我同意其他的回答者说你最好使用其中一个DateTime模块，但是如果你只是在一个文件中读取并想要所有的行被chomp ，那么IO::All应用的chomp和tie选项都非常方便。

另请注意，当将句柄的整个内容直接插入标量时（这就是它的实现方式）， chomp技巧不起作用。

Answer 3

尝试将其放入函数中：

sub autochomp {
    my $command = shift;
    my $retval = `$command`;
    chomp $retval;
    return $retval;
}

然后为每个要执行的命令调用它，然后选择。

Answer 4

在CPAN上使用DateTime或其他日期模块而不是日期实用程序。

例如：

use DateTime;

my $dt = DateTime->now;
print $dt->strftime('%Y%m%d%H%M.%S');

Answer 5

它可以分配和chomp在使用以下语法一行：

chomp ( my $date = `date` );

至于说更多Perlishly，如果你发现自己一遍又一遍地重复同样的事情，把它滚到一个子：

sub assign_and_chomp {

    my @result;
    foreach my $cmd (@_) {
        chomp ( my $chomped = $cmd );
        push @result, $chomped;
    }
    return @result;
}

my ( $date , $datef , $pwd )

   = assign_and_chomp ( `date` , `date +%Y%m%d%H%M.%S` , `pwd` );