[英]Replace part of a string in XML using XSL
我有以下xml:
<links url="../servlet/SearchServlet?query=contact&filter=&sort=relevance&sortdir=desc&col=5&startdate=0&enddate=0&xsl=xml&page=">
<link page="date" url="../servlet/SearchServlet?query=contact&filter=&sort=date&col=5&startdate=0&enddate=0&page=1&xsl=xml"/>
我正在使用此xsl转换链接:
<xsl:for-each select="//link">
<xsl:choose>
<xsl:when test="@page='next'">
<xsl:text></xsl:text>
<a href="{@url}">>></a>
</xsl:when>
<xsl:when test="@page='prev'">
<a href="{@url}"><<</a>
<xsl:text></xsl:text>
</xsl:when>
<xsl:when test="@page='date'"/>
<xsl:when test="@page='relevance'"/>
<xsl:when test="@page='alpha'"/>
</xsl:choose>
</xsl:for-each>
现在最棘手的部分是我想替换从../servlet/SearchServlet
到../search
的链接中的url
部分。
我该如何实现? 我尝试使用此模板,但它替换了整个url
。
<xsl:template match="link/@url">
<xsl:param name="search" select="'../servlet/SearchServlet'" />
<xsl:param name="replace" select="'../search'" />
<xsl:attribute name="href">
<xsl:choose>
<xsl:when test="contains(., $search)">
<xsl:value-of select="concat($replace, substring-after(., $search))" />
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="." />
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</xsl:template>
称为
<a>
<xsl:apply-templates select="@url" />
<xsl:text><<</xsl:text>
</a>
请注意,您可以选择使用
<xsl:apply-templates select="@url" />
<xsl:with-param name="search" select="'xyz'" />
<xsl:with-param name="replace" select="'foo'" />
</xsl:apply-templates>
提供不同的搜索/替换值。
这是一个更简单,更简短的完整解决方案,不使用任何显式的条件指令或xsl:attribute
:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="pTarget" select="'../servlet/SearchServlet'"/>
<xsl:param name="pRep" select="'../search'"/>
<xsl:template match="link">
<xsl:variable name="vCUrl" select="concat(@url, $pTarget)"/>
<a url="{substring-before($vCUrl,$pTarget)}{$pRep}{substring-after(@url,$pTarget)}">
<xsl:apply-templates select="@page"/>
</a>
</xsl:template>
<xsl:template match="link/@page[. = 'next']">>></xsl:template>
<xsl:template match="link/@page[. = 'prev']"><<</xsl:template>
<xsl:template match="link[not(@page='next' or @page='prev')]"/>
</xsl:stylesheet>
当应用于以下XML文档时 :
<links>
<link page="prev" url="../servlet/SearchServlet?query=contact&filter=&sort=relevance&sortdir=desc&col=5&startdate=0&enddate=0&xsl=xml&page="/>
<link page="date" url="../servlet/SearchServlet?query=contact&filter=&sort=date&col=5&startdate=0&enddate=0&page=1&xsl=xml"/>
<link page="next" url="../servlet/SearchServlet?query=contact&filter=&sort=date&col=5&startdate=0&enddate=0&page=1&xsl=xml"/>
</links>
产生想要的正确结果 :
<a url="../search?query=contact&filter=&sort=relevance&sortdir=desc&col=5&startdate=0&enddate=0&xsl=xml&page="><<</a>
<a url="../search?query=contact&filter=&sort=date&col=5&startdate=0&enddate=0&page=1&xsl=xml">>></a>
说明 :
适当使用AVT( 属性值模板 )
适当使用模式匹配和模板。
将标记添加到字符串,以便不需要条件处理。
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.