使用XSL替換XML中的字符串的一部分

Question

我有以下xml：

<links url="../servlet/SearchServlet?query=contact&filter=&sort=relevance&sortdir=desc&col=5&startdate=0&enddate=0&xsl=xml&page=">

<link page="date" url="../servlet/SearchServlet?query=contact&filter=&sort=date&col=5&startdate=0&enddate=0&page=1&xsl=xml"/>

我正在使用此xsl轉換鏈接：

 <xsl:for-each select="//link">

            <xsl:choose>
                <xsl:when test="@page='next'">
                    <xsl:text></xsl:text>
                    <a href="{@url}">&gt;&gt;</a>
                </xsl:when>
                <xsl:when test="@page='prev'">
                    <a href="{@url}">&lt;&lt;</a>
                    <xsl:text></xsl:text>
                </xsl:when>

                <xsl:when test="@page='date'"/>
                <xsl:when test="@page='relevance'"/>
                <xsl:when test="@page='alpha'"/>

            </xsl:choose>
        </xsl:for-each>

現在最棘手的部分是我想替換從../servlet/SearchServlet到../search的鏈接中的url部分。

我該如何實現？ 我嘗試使用此模板，但它替換了整個url 。

Answer 1

<xsl:template match="link/@url">
  <xsl:param name="search"  select="'../servlet/SearchServlet'" />
  <xsl:param name="replace" select="'../search'" />
  <xsl:attribute name="href">
    <xsl:choose>
      <xsl:when test="contains(., $search)">
        <xsl:value-of select="concat($replace, substring-after(., $search))" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="." />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:attribute>
</xsl:template>

稱為

<a>
  <xsl:apply-templates select="@url" />
  <xsl:text>&lt;&lt;</xsl:text>
</a>

請注意，您可以選擇使用

<xsl:apply-templates select="@url" />
  <xsl:with-param name="search"  select="'xyz'" />
  <xsl:with-param name="replace" select="'foo'" />
</xsl:apply-templates>

提供不同的搜索/替換值。

Answer 2

這是一個更簡單，更簡短的完整解決方案，不使用任何顯式的條件指令或xsl:attribute ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pTarget" select="'../servlet/SearchServlet'"/>
 <xsl:param name="pRep" select="'../search'"/>

 <xsl:template match="link">
  <xsl:variable name="vCUrl" select="concat(@url, $pTarget)"/>

  <a url="{substring-before($vCUrl,$pTarget)}{$pRep}{substring-after(@url,$pTarget)}">
   <xsl:apply-templates select="@page"/>
  </a>
 </xsl:template>

 <xsl:template match="link/@page[. = 'next']">>></xsl:template>
 <xsl:template match="link/@page[. = 'prev']">&lt;&lt;</xsl:template>

 <xsl:template match="link[not(@page='next' or @page='prev')]"/>
</xsl:stylesheet>

當應用於以下XML文檔時 ：

<links>
 <link page="prev" url="../servlet/SearchServlet?query=contact&amp;filter=&amp;sort=relevance&amp;sortdir=desc&amp;col=5&amp;startdate=0&amp;enddate=0&amp;xsl=xml&amp;page="/>
 <link page="date" url="../servlet/SearchServlet?query=contact&amp;filter=&amp;sort=date&amp;col=5&amp;startdate=0&amp;enddate=0&amp;page=1&amp;xsl=xml"/>
 <link page="next" url="../servlet/SearchServlet?query=contact&amp;filter=&amp;sort=date&amp;col=5&amp;startdate=0&amp;enddate=0&amp;page=1&amp;xsl=xml"/>
</links>

產生想要的正確結果 ：

<a url="../search?query=contact&amp;filter=&amp;sort=relevance&amp;sortdir=desc&amp;col=5&amp;startdate=0&amp;enddate=0&amp;xsl=xml&amp;page=">&lt;&lt;</a>
<a url="../search?query=contact&amp;filter=&amp;sort=date&amp;col=5&amp;startdate=0&amp;enddate=0&amp;page=1&amp;xsl=xml">&gt;&gt;</a>

說明 ：

1. 適當使用AVT（ 屬性值模板 ）

2. 適當使用模式匹配和模板。

3. 將標記添加到字符串，以便不需要條件處理。