如何通过指定 package 名称列表自动安装 Emacs 包？

Question

我正在使用package来管理我的 Emacs 分机。 为了在不同的计算机上同步我的 Emacs 设置，我想要一种在.emacs文件中指定 package 名称列表的方法，然后package可以自动搜索并安装软件包，这样我就不需要手动安装它们通过调用Mx package-list-packages 。 怎么做？

Answer 1

; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))

Answer 2

Emacs 25.1+ 将在可定制的package-selected-packages变量中自动跟踪用户安装的包。 package-install将更新自定义变量，您可以使用package-install-selected-packages function 安装所有选定的包。

这种方法的另一个方便的优点是您可以使用package-autoremove自动删除未包含在package-selected-packages中的包（尽管它会保留依赖项）。

(package-initialize)
(unless package-archive-contents
  (package-refresh-contents))
(package-install-selected-packages)

资料来源： http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html

Answer 3

根据 Profpatsch 的评论和以下答案：

(defun ensure-package-installed (&rest packages)
  "Assure every package is installed, ask for installation if it’s not.

Return a list of installed packages or nil for every skipped package."
  (mapcar
   (lambda (package)
     ;; (package-installed-p 'evil)
     (if (package-installed-p package)
         nil
       (if (y-or-n-p (format "Package %s is missing. Install it? " package))
           (package-install package)
         package)))
   packages))

;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
    (package-refresh-contents))

(ensure-package-installed 'iedit 'magit) ;  --> (nil nil) if iedit and magit are already installed

;; activate installed packages
(package-initialize)

Answer 4

这是我用于Emacs Prelude的代码：

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

如果你不使用 MELPA，你不需要要求它（如果你这样做， melpa.el必须在你的load-path上（或通过 MELPA 安装）。package db 不会每次都刷新（因为这个会显着减慢启动速度） - 仅在存在已卸载软件包的情况下。

Answer 5

还没有人提到Cask ，但它非常适合这项任务。

基本上你创建~/.emacs.d/Cask列出你想要安装的包。 例如：

(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc

从命令行运行cask将为您安装这些包，以及它们需要的任何依赖项。

此外，您可以使用cask update自动更新已安装的包。

Answer 6

使用名称 package 作为符号调用package-install 。 您可以通过交互式调用package-install并完成名称来找到包的 package 名称。 function package-installed-p会让你知道它是否已经安装。

例如：

(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))

Answer 7

(require 'cl)
(require 'package)

(setq cfg-var:packages '(
       emmet-mode
       ergoemacs-mode
       flycheck
       flycheck-pyflakes
       monokai-theme
       py-autopep8
       py-isort
       rainbow-mode
       yafolding
       yasnippet))

(defun cfg:install-packages ()
    (let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
        (when pkgs
            (message "%s" "Emacs refresh packages database...")
            (package-refresh-contents)
            (message "%s" " done.")
            (dolist (p cfg-var:packages)
                (package-install p)))))

(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)

(cfg:install-packages)

Answer 8

我喜欢检查用户是否想先安装软件包，就像在这个答案中所做的那样。 此外，在安装任何内容之前，我会刷新我的 package 内容一次。 我不确定这是否是最好的方法，但我不认为最重要的答案是为我做的。

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

Answer 9

这是我的，它更短:)

(mapc
 (lambda (package)
   (unless (package-installed-p package)
     (progn (message "installing %s" package)
            (package-refresh-contents)
            (package-install package))))
 '(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))

Answer 10

我遇到了一个问题，在将(package-install 'org)添加到.emacs后没有任何反应。 我想安装最新版本的org-mode而内置的org-mode已经很旧了。

我从Emacs 25.3.1挖出了package-install的源码。 function self 已经检查是否安装了 package，如果已经安装了 package，则拒绝安装。 所以答案10093312中的检查(unless (package-installed-p package)...)实际上是不需要的。

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

内置的org-mode也算作已安装，而package-install拒绝安装来自 ELPA 的更新版本。 花了一些时间阅读 package.el 后，我想到了以下解决方案。

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

它起作用的原因是package-*系列函数根据它是符号还是package-desc object 以不同方式处理 arguments。您只能通过package-desc object 指定package-install的版本信息。

Answer 11

这是另一种方式。

;; assure every package is installed
(defun ensure-package-installed (&rest packages)
  (let ((user-required-packages
         (seq-remove
          (lambda (package) (package-installed-p package))
          packages)))
    (when user-required-packages
      (package-refresh-contents)
      (dolist (package user-required-packages)
        (package-install package)))))

;; list of packages to install
(ensure-package-installed
 'try
 'which-key)

Answer 12

接近尼古拉斯的回答：

如果本地不存在包package-1 、 package-2和package-3 ，则安装它们。 如果它们存在，则 Emacs 会立即加载。

(setq package-archives                                      ;
      '(("gnu" . "https://elpa.gnu.org/packages/")          ; declare repositories
        ("melpa" . "https://melpa.org/packages/")))         ;

(require 'package)                                          ; activate packages
(package-initialize)                                        ; initialize package facility

(setq my-packages
      '(package-1
        package-2
        package-3))

(unless package-archive-contents                            ; unless packages are not available locally, dont refresh package archives
  (package-refresh-contents))                               ; refreshing package contents is time-consuming and should be done on demand

(dolist (pkg my-packages)                                   ;
  (unless (package-installed-p pkg)                         ; iterate over packages and install missing ones
    (package-install pkg)))                                 ;

;; other config below