Java中生成的Antlr解析器：并非所有输入都被读取

Question

我正在使用我的Antlr语法来使用Java解析多个变量中的多项式函数。 合法输入的例子是

42; X; +42X; Y^42; 1337HelloWorld; 13,37X^42; 

以下语法编译时没有警告或错误：

grammar Function;

parseFunction returns [java.util.List<java.util.List<Object>> list] :   
    { list = new java.util.ArrayList(); }                                              ( f=functionPart { list.add($f.list); } )+
|   { list = new java.util.ArrayList(); } ( fb=functionBegin ) { list.add($fb.list); } ( f=functionPart { list.add($f.list); } )*
;

functionBegin returns [java.util.List<Object> list]:
m=NUMBER v=VARIABLE e=exponent  { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add($v.text); list.add($e.value); }
| m=NUMBER v=VARIABLE           { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); list.add($v.text); }
| v=VARIABLE e=exponent         { list = new java.util.ArrayList(); list.add("+"); list.add("1");     list.add($v.text); list.add($e.value); }  
| v=VARIABLE                    { list = new java.util.ArrayList(); list.add("+"); list.add("1");     list.add($v.text); }
| m=NUMBER                      { list = new java.util.ArrayList(); list.add("+"); list.add($m.text); }
;

functionPart returns [java.util.List<Object> list] :    
s=SIGN m=NUMBER v=VARIABLE e=exponent   { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add($v.text); list.add($e.value); }
| s=SIGN m=NUMBER v=VARIABLE            { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); list.add($v.text); }
| s=SIGN v=VARIABLE e=exponent          { list = new java.util.ArrayList(); list.add($s.text); list.add("1");     list.add($v.text); list.add($e.value); }
| s=SIGN v=VARIABLE                     { list = new java.util.ArrayList(); list.add($s.text); list.add("1");     list.add($v.text); }
| s=SIGN m=NUMBER                       { list = new java.util.ArrayList(); list.add($s.text); list.add($m.text); }
;

exponent returns [int value]: ('^' n=INTEGER) { $value = 1; if ( $n != null && $n.text.length() > 0) $value = Integer.parseInt($n.text); }
;

VARIABLE    : ('a'..'z'|'A'..'Z')+
;

INTEGER : ('0'..'9')+
;

NUMBER  : ('0'..'9')+ (','('0'..'9')+)?
;

SIGN    :   ('+'|'-')
;

WS  :    (' ' | '\t' | '\r'| '\n')+ {skip();} 
;

如果在Java中编译和使用该语法，则接受大多数输入值。 显然，并非所有有效输入值都被接受。 一旦不使用逗号的数字弹出，就像输入一样

+42; 42; 42X^1337; 

抛出错误（来自输入“+42”的错误）：

line 1:1 no viable alternative at input '+'

如果我修改输入，则不会抛出错误

+42,0; 42,0; 42,0X^1337

任何人都可以说，为什么以及如何解决它？

Answer 1

具有最长匹配的第一个词法分析器获胜，因此42是INTEGER ，并且NUMBER实际上仅在逗号部分存在时匹配，即当NUMBER具有比INTEGER更长的匹配时。

这可以通过添加解析器规则来修复

number : NUMBER | INTEGER ;

并使用它而不是其他解析器规则中的NUMBER 。