如何在AWK中一次删除多个列和字段分隔符？

Question

我有一个包含数千列的大文件。 我想在Bash中使用AWK一次删除一些特定的列和字段分隔符。

我可以使用此oneliner一次删除一列（第3列将被删除，其对应的字段分隔符）：

awk -vkf=3 -vFS="\t" -vOFS="\t" '{for(i=kf; i<NF;i++){ $i=$(i+1);}; NF--; print}' < Big_File

但是，我想一次删除几个列...有人可以帮我解决这个问题吗？

Answer 1

您可以将要从shell中删除的列的列表传递给awk如下所示：

awk -vkf="3,5,11" ...

然后在awk程序中将其解析为数组：

split(kf,kf_array,",")

然后通过所有列并测试每个特定列是否在kf_array中并可能跳过它

其他可能性是多次打电话给你的oneliner :-)

Answer 2

以下是卡米尔的想法的实现：

awk -v remove="3,8,5" '
  BEGIN {
    OFS=FS="\t"
    split(remove,a,",")
    for (i in a) b[a[i]]=1
  }                                                          
  {
    j=1
    for (i=1;i<=NF;++i) {
      if (!(i in b)) { 
        $j=$i
        ++j
      }
    }
    NF=j-1
    print
  }
'

Answer 3

如果你可以使用cut而不是awk ，这个更容易cut ：

例如，这会从文件中获取列1,3和50：

cut -f1,3,50- file

Answer 4

这样的事情应该有效：

awk -F'\t' -v remove='3|8|5' '
{
   rec=ofs=""
   for (i=1;i<=NF;i++) {
      if (i !~ "^(" remove ")$" ) {
         rec = rec ofs $i
         ofs = FS
      }
   }
   print rec
}
' file