cmd字符串替換特殊字符

Question

我試圖在批處理腳本中用%HOME%替換~ 。 這是我到目前為止：

@echo off
setlocal enabledelayedexpansion
set str=%*
set replacement=%HOME%
set str=%str:~=!replacement!%
echo %str%

這不會像我期望的那樣起作用，大概是因為我需要以某種方式逃避波浪號~ 。

當我用^轉義時， str不變。 沒有轉義， str是字符串str:~=<my_home_path> 。

如何將"~/work/my_folder"更改為"C:/Users/login/work/my_folder" ？

Answer 1

如果~總是第一個字符，你可以使用如下：

@echo off &setlocal enabledelayedexpansion
set "str=|~/work/my_folder"
set "replacement=C:/Users/login"
set str=%str:|~=!replacement!%
echo %str%

Answer 2

或者更復雜一點：

@echo off &setlocal enabledelayedexpansion
set "str=~/work/my_folder -param one ~ two:~"
set "replacement=C:/Users/login"
call :strlen str len
set /a len-=1
for /l %%i in (0,1,%len%) do if "!str:~%%i,1!"=="~" (set "new=!new!%replacement%") else set "new=!new!!str:~%%i,1!"
echo %new%
goto :eof

:strlen
:: list string length up to 8189 (and reports 8189 for any string longer than 8189)
:: function from http://ss64.org/viewtopic.php?pid=6478#p6478
(   setlocal enabledelayedexpansion & set /a "}=0"
    if "%~1" neq "" if defined %~1 (
        for %%# in (4096 2048 1024 512 256 128 64 32 16) do (
            if "!%~1:~%%#,1!" neq "" set "%~1=!%~1:~%%#!" & set /a "}+=%%#"
        )
        set "%~1=!%~1!0FEDCBA9876543211" & set /a "}+=0x!%~1:~32,1!!%~1:~16,1!"
    )
)
endlocal & set /a "%~2=%}%" & exit /b
endlocal

輸出：

C:/Users/login/work/my_folder -param one C:/Users/login two:C:/Users/login

這不適用於感嘆號。

Answer 3

除了一些小問題之外，我認為你已經非常接近了。

首先，對於%home% ，Windows中可能沒有環境變量 - 至少在我的系統上沒有。 我認為您要查找的變量是%userprofile% 。 ss64.com有一個很好的Windows環境變量列表和描述。

另一個問題是你以錯誤的順序推遲擴張。 嘗試更改倒數第二行以set str=!str:~=%userprofile%! 以便內部變量在外部之前擴展。 將正斜杠向后翻譯可能也不是一個壞主意。

@echo off
setlocal enabledelayedexpansion
set str=%*
set "str=!str: ~= %userprofile%!"
set "str=!str:*~=%userprofile%!"
set "str=%str:\=/%"
echo %str%

示例輸出：

C:\Users\me\Desktop>test ~/.bash_profile
C:/Users/me/.bash_profile

C:\Users\me\Desktop>test arg1 arg2 ~/.bash_profile
arg1 arg2 C:/Users/me/.bash_profile

Answer 4

    @ECHO OFF
    CLS
    SET OldStr=~\work\my_folder
    SET NewStr=
    SET Replacement=C:\Users\login\work\my_folder
    CALL :ReplaceHome "%OldStr%"
    ECHO %NewStr%
    EXIT /b %ERRORLEVEL%

    :ReplaceHome
    IF "%~1"=="" EXIT /B %ERRORLEVEL%
    SET TempStr=%~1
    IF "%TempStr:~0,1%"=="~" SET TempStr=%Replacement%%TempStr:~1%
    SET NewStr=%NewStr%%TempStr:~0,1%
    CALL :ReplaceHome "%TempStr:~1%"
    EXIT /B %ERRORLEVEL%