[英]delphi and opengl: light is rotating with the cube
問題是由翻譯寫的,所以我不知道這在字面上是正確的。 我開始學習Opengl並遇到以下問題:旋轉立方體時,燈光也會旋轉。 我試圖在每一幀中更改光的坐標,但這沒有幫助。 告訴我:出了什么問題。 如果沒有麻煩,則有可能導致修訂版本。
碼:
unit MainUnit;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs,dglOpenGL,dglut;
type
TFMainForm = class(TForm)
procedure FormCreate(Sender: TObject);
procedure FormResize(Sender: TObject);
procedure FormDestroy(Sender: TObject);
procedure FormKeyPress(Sender: TObject; var Key: Char);
private
procedure SetupGL;
procedure uzglLightEnable;
procedure IdleHandler(Sender : TObject; var Done : Boolean);
public
procedure Render;
end;
var
FMainForm: TFMainForm;
dc:hdc;
hrc:hglrc;
XRot,YRot,ZRot:Single;
LightPos:TGLArrayf4;
BlueArray:TGLArrayf4;
GreenArray:TGLArrayf4;
myTex: glUint;
FrontNormal: TGLvectorf3=(0,0,1);
BackNormal: TGLvectorf3 =(0,0,-1);
LeftNormal: TGLvectorf3 =(-1,0,0);
RightNormal: TGLvectorf3=(1,0,0);
UpNormal: TGLvectorf3 =(0,1,0);
DownNormal: TGLvectorf3 =(0,-1,0);
FrontDownLeft :TGLvectorf3 = (-1,-1,-1);
FrontDownRight:TGLvectorf3 = (1,-1,-1);
FrontUpLeft :TGLvectorf3 = (-1,1,-1);
FrontUpRight :TGLvectorf3 = (1,1,-1);
BackDownLeft :TGLvectorf3 = (-1,-1,1);
BackDownRight:TGLvectorf3 = (1,-1,1);
BackUpLeft :TGLvectorf3 = (-1,1,1);
BackUpRight :TGLvectorf3 = (1,1,1);
const
NearClipping = 0.1;
FarClipping = 200;
procedure uzglTriangle(x1,y1,z1,x2,y2,z2,x3,y3,z3:single);
procedure uzglCube;
implementation
{$R *.dfm}
procedure uzglTriangle(x1,y1,z1,x2,y2,z2,x3,y3,z3:single);
begin
glBegin(GL_TRIANGLES);
glColor3f(0.3,0,0);glVertex3f(x1,y1,z1);
glColor3f(0.25,1,0);glVertex3f(x2,y2,z2);
glColor3f(0.7,0,1);glVertex3f(x3,y3,z3);
glEnd;
end;
procedure uzglCube;
begin
glBegin(GL_QUADS);
// Beginning of front
glNormal3fv(@FrontNormal);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontUpRight);
glVertex3fv(@FrontUpLeft);
// End of front
glEnd;
glBegin(GL_QUADS);
// Beginning of left
glNormal3fv(@LeftNormal);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@FrontUpLeft);
glVertex3fv(@BackUpLeft);
glVertex3fv(@BackDownLeft);
// End of left
glEnd;
glBegin(GL_QUADS);
// Beginning of right
glNormal3fv(@RightNormal);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontUpRight);
glVertex3fv(@BackUpRight);
glVertex3fv(@BackDownRight);
// End of right
glEnd;
glBegin(GL_QUADS);
// Beginning of up
glNormal3fv(@UpNormal);
glVertex3fv(@FrontUpRight);
glVertex3fv(@FrontUpLeft);
glVertex3fv(@BackUpLeft);
glVertex3fv(@BackUpRight);
// End of up
glEnd;
glBegin(GL_QUADS);
// Beginning of down
glNormal3fv(@DownNormal);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@BackDownLeft);
glVertex3fv(@BackDownRight);
// End of down
glEnd;
glBegin(GL_QUADS);
// Beginning of back
glNormal3fv(@BackNormal);
glVertex3fv(@BackDownLeft);
glVertex3fv(@BackDownRight);
glVertex3fv(@BackUpRight);
glVertex3fv(@BackUpLeft);
// End of back
glEnd;
end;
procedure TFMainForm.SetupGL;
begin
glClearColor(0.3,0.4,0.7,0.0);
glEnable(GL_DEPTH_TEST);
glEnable(GL_SMOOTH);
glDepthFunc(GL_LEQUAL);
glEnable(GL_TEXTURE_2D);
uzglLightEnable;
LightPos[0]:=0;
LightPos[1]:=0;
LightPos[2]:=1;
LightPos[3]:=1;
end;
procedure TFMainForm.uzglLightEnable;
begin
glEnable(GL_LIGHTING);
glEnable(GL_LIGHT0);
glEnable(GL_COLOR_MATERIAL);
end;
procedure TFMainForm.Render;
var i:integer;
begin
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);
glTranslatef(0,0,-5);
glPushMatrix;
glRotatef(XRot,1,0,0);
uzglCube;
glPopMatrix;
glLightfv(GL_LIGHT0, GL_POSITION,@LightPos);
SwapBuffers(dc);
XRot:=XRot+1;
end;
procedure TFMainForm.IdleHandler(Sender : TObject; var Done : Boolean);
begin
Render;
Sleep(25);
Done:=false;
end;
procedure TFMainForm.FormCreate(Sender: TObject);
begin
dc:=GetDC(Handle);
if not InitOpenGL then
begin
ShowMessage('Печалька... Инициализация провалилась');
Application.Terminate;
end;
hrc:=CreateRenderingContext (dc,
[opDoubleBuffered],
32,
24,
8,
0,
0,
0);
ActivateRenderingContext(dc,hrc);
SetupGL;
Application.OnIdle:=IdleHandler;
FMainForm.OnResize(self);
end;
procedure TFMainForm.FormResize(Sender: TObject);
var tmpBool:boolean;
begin
glViewport(0,0,ClientWidth,ClientHeight);
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
idleHandler(Sender, tmpBool);
end;
procedure TFMainForm.FormDestroy(Sender: TObject);
begin
DeactivateRenderingContext;
DestroyRenderingContext(hrc);
ReleaseDC(Handle,dc);
end;
procedure TFMainForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case key of
'q':LightPos[0]:=LightPos[0]+0.1;
'a':LightPos[0]:=LightPos[0]-0.1;
'w':LightPos[1]:=LightPos[1]+0.1;
's':LightPos[1]:=LightPos[1]-0.1;
'e':LightPos[2]:=LightPos[2]+0.1;
'd':LightPos[2]:=LightPos[2]-0.1;
end;
end;
end.
dglOpenGL: http ://wiki.delphigl.com/index.php/dglOpenGL.pas/en
我可以發現一些錯誤的地方。
首先:您的法線不一致。 改成
FrontNormal: TGLvectorf3=(0,0,1);
BackNormal: TGLvectorf3 =(0,0,-1);
LeftNormal: TGLvectorf3 =(1,0,0);
RightNormal: TGLvectorf3=(-1,0,0);
UpNormal: TGLvectorf3 =(0,-1,0);
DownNormal: TGLvectorf3 =(0,1,0);
其次:您正在GL_PROJECTION矩陣中轉換多維數據集。 GL_PROJECTION矩陣應僅包含設置投影所需的內容。
您的立方體和燈光應通過GL_MODELVIEW矩陣進行變換。
僅當窗口大小更改時,Projection才會更改,因此可以在FormResize事件中使用。
procedure TForm2.FormResize(Sender: TObject);
var tmpBool:boolean;
begin
glViewport(0,0,ClientWidth,ClientHeight);
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);
idleHandler(Sender, tmpBool);
end;
GL_MODELVIEW矩陣可以在SetupGL proc中設置。 請注意gluLookAt()命令,該命令設置了從(-2,3,-3)到(0,0,0)的視圖。 設置gluLookAt(0,3,-3,0,0,0,0,1,0); 具有“正面”看法。
procedure TForm2.SetupGL;
begin
glClearColor(0.3,0.4,0.7,0.0);
glEnable(GL_DEPTH_TEST);
glEnable(GL_SMOOTH);
glDepthFunc(GL_LEQUAL);
glEnable(GL_TEXTURE_2D);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
gluLookAt(-2, 3, -3, 0,0,0, 0,1,0);
uzglLightEnable;
LightPos[0]:=0;
LightPos[1]:=0;
LightPos[2]:=1;
LightPos[3]:=1;
end;
渲染過程變為。
procedure TForm2.Render;
var i:integer;
begin
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
glMatrixMode(GL_MODELVIEW);
glPushMatrix;
glRotatef(XRot,1,0,0);
uzglCube;
if FTransformLights then
begin
glLightfv(GL_LIGHT0, GL_POSITION,@LightPos);
glPopMatrix;
end
else
begin
glPopMatrix;
glLightfv(GL_LIGHT0, GL_POSITION,@LightPos);
end;
SwapBuffers(dc);
XRot:=XRot+1;
end;
注意:我添加了一個私有表單變量FTransformLights,如果為true,則將其隨多維數據集一起旋轉,否則,在GL_MODELVIEW矩陣“彈出”回到其原始狀態(標識)后,由於變換后的燈光不會旋轉。
我添加了“ x”鍵來切換燈光是否旋轉。 這是完整的修改清單。 希望能解決它。
unit MainUnit;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs,dglOpenGL;
type
TFMainForm = class(TForm)
procedure FormCreate(Sender: TObject);
procedure FormResize(Sender: TObject);
procedure FormDestroy(Sender: TObject);
procedure FormKeyPress(Sender: TObject; var Key: Char);
private
FTransformLights:Boolean;
procedure SetupGL;
procedure uzglLightEnable;
procedure IdleHandler(Sender : TObject; var Done : Boolean);
public
procedure Render;
end;
var
FMainForm: TFMainForm;
dc:hdc;
hrc:hglrc;
XRot,YRot,ZRot:Single;
LightPos:TGLArrayf4;
BlueArray:TGLArrayf4;
GreenArray:TGLArrayf4;
myTex: glUint;
FrontNormal: TGLvectorf3=(0,0,1);
BackNormal: TGLvectorf3 =(0,0,-1);
LeftNormal: TGLvectorf3 =(1,0,0);
RightNormal: TGLvectorf3=(-1,0,0);
UpNormal: TGLvectorf3 =(0,-1,0);
DownNormal: TGLvectorf3 =(0,1,0);
FrontDownLeft :TGLvectorf3 = (-1,-1,-1);
FrontDownRight:TGLvectorf3 = (1,-1,-1);
FrontUpLeft :TGLvectorf3 = (-1,1,-1);
FrontUpRight :TGLvectorf3 = (1,1,-1);
BackDownLeft :TGLvectorf3 = (-1,-1,1);
BackDownRight:TGLvectorf3 = (1,-1,1);
BackUpLeft :TGLvectorf3 = (-1,1,1);
BackUpRight :TGLvectorf3 = (1,1,1);
const
NearClipping = 0.1;
FarClipping = 200;
procedure uzglTriangle(x1,y1,z1,x2,y2,z2,x3,y3,z3:single);
procedure uzglCube;
implementation
{$R *.dfm}
procedure uzglTriangle(x1,y1,z1,x2,y2,z2,x3,y3,z3:single);
begin
glBegin(GL_TRIANGLES);
glColor3f(0.3,0,0);glVertex3f(x1,y1,z1);
glColor3f(0.25,1,0);glVertex3f(x2,y2,z2);
glColor3f(0.7,0,1);glVertex3f(x3,y3,z3);
glEnd;
end;
procedure uzglCube;
begin
glBegin(GL_QUADS);
// Beginning of front
glNormal3fv(@FrontNormal);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontUpRight);
glVertex3fv(@FrontUpLeft);
// End of front
glEnd;
glBegin(GL_QUADS);
// Beginning of left
glNormal3fv(@LeftNormal);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@FrontUpLeft);
glVertex3fv(@BackUpLeft);
glVertex3fv(@BackDownLeft);
// End of left
glEnd;
glBegin(GL_QUADS);
// Beginning of right
glNormal3fv(@RightNormal);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontUpRight);
glVertex3fv(@BackUpRight);
glVertex3fv(@BackDownRight);
// End of right
glEnd;
glBegin(GL_QUADS);
// Beginning of up
glNormal3fv(@UpNormal);
glVertex3fv(@FrontUpRight);
glVertex3fv(@FrontUpLeft);
glVertex3fv(@BackUpLeft);
glVertex3fv(@BackUpRight);
// End of up
glEnd;
glBegin(GL_QUADS);
// Beginning of down
glNormal3fv(@DownNormal);
glVertex3fv(@FrontDownRight);
glVertex3fv(@FrontDownLeft);
glVertex3fv(@BackDownLeft);
glVertex3fv(@BackDownRight);
// End of down
glEnd;
glBegin(GL_QUADS);
// Beginning of back
glNormal3fv(@BackNormal);
glVertex3fv(@BackDownLeft);
glVertex3fv(@BackDownRight);
glVertex3fv(@BackUpRight);
glVertex3fv(@BackUpLeft);
// End of back
glEnd;
end;
procedure TFMainForm.SetupGL;
begin
glClearColor(0.3,0.4,0.7,0.0);
glEnable(GL_DEPTH_TEST);
glEnable(GL_SMOOTH);
glDepthFunc(GL_LEQUAL);
glEnable(GL_TEXTURE_2D);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
gluLookAt(-2, 3, -3, 0,0,0, 0,1,0);
uzglLightEnable;
LightPos[0]:=0;
LightPos[1]:=0;
LightPos[2]:=1;
LightPos[3]:=1;
end;
procedure TFMainForm.uzglLightEnable;
begin
glEnable(GL_LIGHTING);
glEnable(GL_LIGHT0);
glEnable(GL_COLOR_MATERIAL);
end;
procedure TFMainForm.Render;
begin
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
glMatrixMode(GL_MODELVIEW);
glPushMatrix;
glRotatef(XRot,1,0,0);
uzglCube;
if FTransformLights then
begin
glLightfv(GL_LIGHT0, GL_POSITION,@LightPos);
glPopMatrix;
end
else
begin
glPopMatrix;
glLightfv(GL_LIGHT0, GL_POSITION,@LightPos);
end;
SwapBuffers(dc);
XRot:=XRot+1;
end;
procedure TFMainForm.IdleHandler(Sender : TObject; var Done : Boolean);
begin
Render;
Sleep(25);
Done:=false;
end;
procedure TFMainForm.FormCreate(Sender: TObject);
begin
dc:=GetDC(Handle);
if not InitOpenGL then
begin
ShowMessage('????????... ????????????? ???????????');
Application.Terminate;
end;
hrc:=CreateRenderingContext (dc,
[opDoubleBuffered],
32,
24,
8,
0,
0,
0);
ActivateRenderingContext(dc,hrc);
FTransformLights:=false;
SetupGL;
Application.OnIdle:=IdleHandler;
FMainForm.OnResize(self);
end;
procedure TFMainForm.FormResize(Sender: TObject);
var tmpBool:boolean;
begin
glViewport(0,0,ClientWidth,ClientHeight);
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);
idleHandler(Sender, tmpBool);
end;
procedure TFMainForm.FormDestroy(Sender: TObject);
begin
DeactivateRenderingContext;
DestroyRenderingContext(hrc);
ReleaseDC(Handle,dc);
end;
procedure TFMainForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case key of
'q':LightPos[0]:=LightPos[0]+0.1;
'a':LightPos[0]:=LightPos[0]-0.1;
'w':LightPos[1]:=LightPos[1]+0.1;
's':LightPos[1]:=LightPos[1]-0.1;
'e':LightPos[2]:=LightPos[2]+0.1;
'd':LightPos[2]:=LightPos[2]-0.1;
'x':FTransformLights:=NOT FTransformLights;
end;
end;
end.
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.