IIS 7中的應用程序池狀態

Question

我想獲取應用程序池的狀態。 我從這里取了vbscript。

strArgAppPool = Wscript.Arguments.Unnamed.Item(0)
Const noError = False

' Establish the connection to the WMI provider
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")

' Search the AppPool passed as argument in the list of application pools
Set oAppPool = oWebAdmin.Get("ApplicationPool.Name='" & strArgAppPool & "'")

' Create nice messages for pool states
Select Case oAppPool.GetState      

    Case 0            
        StateDescription = "STARTING"        
        outputStatus = "WARNING! "
        outputCode = 1
    Case 1            
        StateDescription = "STARTED"        
        outputStatus = "OK! "
        outputCode = 0
    Case 2            
        StateDescription = "STOPPING"
        outputStatus = "WARNING! "
        outputCode = 1
    Case 3            
        StateDescription = "STOPPED"        
        outputStatus = "CRITICAL!! "
        outputCode = 2
    Case 4            
        StateDescription = "UNKNOWN"        
        outputStatus = "UNKNOWN? "
        outputCode = 3
    Case Else   
        StateDescription = "UNDEFINED VALUE"    
        outputStatus = "UNKNOWN? "
        outputCode = 3

End Select

' Output
Wscript.Echo outputStatus & oAppPool.Name & ": " & StateDescription

' Error handling
If noError = true Then
    ' Error message
    Wscript.echo "UNKNOWN: Error during the WMI query for app pool " & strArgAppPool & " !"
    ' Exit & return code
    WScript.Quit(3)
Else
    ' Clean exit
    WScript.Quit(outputCode)
End If

通過一個批處理文件，我試圖以

status1.vbs "DefaultAppPool"

但是我最終還是這樣

某些服務沒有啟動嗎？ 我嘗試直接運行vb腳本。 我嘗試傳遞不帶引號和所有類似內容的參數。 我不編寫腳本，但是這次必須這樣做。

錯誤對話框指示第5行， Set oWebAdmin = GetObject("winmgmts:root\\WebAdministration") 。 在過去的5個小時中，我已盡一切可能。 我有一個現成的腳本，但我無法運行它。 感到羞恥，並且一直不願意發布這個問題。 但是最終輸了。 謝謝你的幫助。

另外，我還有一個適用於IIS 6的腳本。我正在通過遠程服務器上的PsExec調用此腳本。 但這在IIS 7中不起作用。讓我知道是否有人要我發布它。 另外，我現在正在使用IIS 7和Server 2008 R2，並將在遠程服務器上使用PsExec運行此腳本。

Answer 1

您沒有安裝角色服務IIS管理腳本和工具 。 啟動服務器管理器，轉到角色→Web服務器（IIS） ，然后安裝缺少的服務。