圍繞容器的中心點旋轉圖像

Question

我在clipAndEnableScrolling屬性設置為true的某個容器中有Image組件。 我需要一個靜態方法來獲取此Image ，旋轉角度並圍繞容器的中心點旋轉Image而不丟失任何先前的變換。 我創建的最佳方法幾經旋轉會增加錯誤。

我認為它必須像這樣工作

        public static function rotateImageAroundCenterOfViewPort(image:Image, value:int):void
    {
        // Calculate rotation and shifts
        var bounds:Rectangle = image.getBounds(image.parent);
        var angle:Number = value - image.rotation;
        var radians:Number = angle * (Math.PI / 180.0);
        var shiftByX:Number = image.parent.width / 2 - bounds.x;
        var shiftByY:Number = image.parent.height / 2 - bounds.y;
        // Perform rotation
        var matrix:Matrix = new Matrix();
        matrix.translate(-shiftByX, -shiftByY);
        matrix.rotate(radians);
        matrix.translate(+shiftByX, +shiftByY);
        matrix.concat(image.transform.matrix);
        image.transform.matrix = matrix;
    }

但事實並非如此。 看起來我不明白轉換的工作原理（

Answer 1

如果您想圍繞對象的中心旋轉對象，我想您會需要更多類似的東西：

var matrix:Matrix = image.transform.matrix;
var rect:Rectangle = image.getBounds( insertParentObject );
//translate matrix to center
matrix.translate(- ( rect.left + ( rect.width/2 ) ), - ( rect.top + ( rect.height/2 ) ) ); 

matrix.rotate(radians); 

//translate back
matrix.translate(rect.left + ( rect.width/2 ), rect.top + ( rect.height/2 ) ); 
image.transform.matrix = matrix;

另外，這里是指向同一SO問題的鏈接，其中包含我提供的答案，答案各不相同：

Flex / ActionScript-圍繞其中心旋轉Sprite

正如評論中所討論的，如果您希望圍繞某個點（即容器的中心）旋轉對象，則可以使用以下函數：

//pass rotateAmount as the angle you want to rotate in degrees
private function rotateAround( rotateAmount:Number, obj:DisplayObject, origin:Point, distance:Number = 100 ):void {
    var radians:Number = rotateAmount * Math.PI / 180;
    obj.x = origin.x + distance * Math.cos( radians );
    obj.y = origin.y + distance * Math.sin( radians );
}

然后，您只需調用它：

rotationAround（rotateAmount，圖像，新Point（container.width / 2，container.height / 2））;

您可以根據需要傳遞最后一個參數distance ，例如，如果我想要一個圖像矢量長度的距離：

var dx:Number = spr.x - stage.stageWidth/2;
var dy:Number = spr.y - stage.stageHeight/2;
var dist:Number = Math.sqrt(dx * dx + dy * dy);
rotateAround( rotateAmount, image, new Point( container.width/2, container.height/2 ), dist );

Answer 2

這是我找到的解決方案：

public static function rotateImageAroundCenterOfViewPort(image:Image, value:int):void
{
    // Calculate rotation and shifts
    var center:Point = new Point(image.parent.width / 2, image.parent.height / 2);
    center = image.parent.localToGlobal(center);
    center = image.globalToLocal(center);
    var angle:Number = value - image.rotation;
    var radians:Number = angle * (Math.PI / 180.0);
    var shiftByX:Number = center.x;
    var shiftByY:Number = center.y;
    // Perform rotation
    var matrix:Matrix = new Matrix();           
    matrix.translate(-shiftByX, -shiftByY);
    matrix.rotate(radians);
    matrix.translate(+shiftByX, +shiftByY);
    matrix.concat(image.transform.matrix);
    image.transform.matrix = matrix;
    image.rotation = Math.round(image.rotation);
}

僅使用諸如90、180等的角度進行測試（我不需要任何其他方法）。