在散列的 Perl 散列中引用散列鍵鏈

Question

我有一個散列的散列存儲數據

our %deviceSettings = (
  BB => {
          EUTRA => {
            DL => { CPC => "NORM", PLCI => { CID => 88 }, ULCPc => "NORM" },
            UL => {
                    REFSig  => { DSSHift => 2, GRPHopping => 1, SEQHopping => 1 },
                    SOFFset => 0,
                  },
          },
        },
  ...
);

我可以遍歷結構並找到一個特定的鍵，比如CID ，然后檢索它的值並將“路徑”存儲在一個數組('BB', 'EUTRA', 'DL', 'PLCI') 。

我也可以像這樣顯式設置一個值

$deviceSettings_ref->{BB}{EUTRA}{DL}{PLCI}{CID} = 99

但我想知道如何使用發現的路徑以編程方式設置值。

Answer 1

您可以使用占位符$hashref哈希：

my $hashref = \%deviceSettings;

$hashref = $hashref->{$_} for qw(BB EUTRA DL PLCI);
$hashref->{CID} = 'My New Path';

use Data::Dump;
dd \%deviceSettings;

輸出：

{
  BB => {
          EUTRA => {
            DL => { CPC => "NORM", PLCI => { CID => "My New Path" }, ULCPc => "NORM" },
            UL => {
                    REFSig  => { DSSHift => 2, GRPHopping => 1, SEQHopping => 1 },
                    SOFFset => 0,
                  },
          },
        },
}

Answer 2

Data::Diver是一個使用路徑訪問嵌套結構的模塊。

use Data::Diver 'DiveVal';

my $device_settings_rf = {};
my @path = ( 'BB', 'EUTRA', 'DL', 'PLCI', 'CID' );
DiveVal( $device_settings_rf, \(@path) ) = 99;