[英]No toolbar buttons when using SLVC_FULLSCREEN with REUSE_ALV_GRID_DISPLAY
我編寫了 SAP Press 書籍ABAP Basics 清單 5.1 中的ABAP 程序。
一切正常,除了我無法顯示任何用於執行/刪除操作的圖標,這些圖標是我使用slvc_fullscreen
從reuse_alv_grid_display
添加的。 當我刪除功能時,我什至看不到屏幕上的后退按鈕。 有什么建議?
REPORT ZPTB00_HOTEL_RESERVATION_COOL.
TYPE-POOLS slis.
* main menu as selection screen
SELECTION-SCREEN BEGIN OF SCREEN 110.
SELECTION-SCREEN BEGIN OF BLOCK b110 WITH FRAME TITLE TEXT-001.
PARAMETERS:
p_add TYPE c RADIOBUTTON GROUP grp1 DEFAULT 'X',
p_delete TYPE c RADIOBUTTON GROUP grp1,
p_show TYPE c RADIOBUTTON GROUP grp1.
SELECTION-SCREEN END OF BLOCK b110.
SELECTION-SCREEN END OF SCREEN 110.
* input new reservation
SELECTION-SCREEN BEGIN OF SCREEN 120.
SELECTION-SCREEN BEGIN OF BLOCK b120 WITH FRAME TITLE TEXT-002.
PARAMETERS:
p_room TYPE zptb00_room_number VALUE CHECK,
p_chkin TYPE zptb00_check_in,
p_chkout TYPE zptb00_check_out,
p_name TYPE zptb00_customer_name.
SELECTION-SCREEN END OF BLOCK b120.
SELECTION-SCREEN END OF SCREEN 120.
DO.
CALL SELECTION-SCREEN 110.
IF sy-subrc <> 0.
EXIT.
ELSEIF p_add = 'X'.
PERFORM zptb00_hrc_add.
ELSEIF p_delete = 'X'.
PERFORM zptb00_hrc_delete.
ELSEIF p_show = 'X'.
PERFORM zptb00_hrc_show.
ENDIF.
ENDDO.
FORM zptb00_hrc_add.
DATA: l_str_reservation TYPE zptb00_hreservat,
l_tab_reservation TYPE STANDARD TABLE OF zptb00_hreservat.
* call input dailog
CALL SELECTION-SCREEN 120 STARTING AT 5 5.
IF sy-subrc = 0.
SELECT * FROM zptb00_hreservat INTO TABLE l_tab_reservation
WHERE ( room_number = p_room ) AND ( ( checkin BETWEEN p_chkin AND p_chkout ) OR ( checkout BETWEEN p_chkin AND p_chkout ) ).
IF sy-dbcnt > 0.
MESSAGE s000(zptb00_messages_alv).
ELSE.
CALL FUNCTION 'GUID_CREATE'
IMPORTING
ev_guid_32 = l_str_reservation-id.
l_str_reservation-room_number = p_room.
l_str_reservation-checkin = p_chkin.
l_str_reservation-checkout = p_chkout.
l_str_reservation-customername = p_name.
INSERT zptb00_hreservat FROM l_str_reservation.
MESSAGE s001(zptb00_messages_alv).
ENDIF.
ENDIF.
ENDFORM.
FORM zptb00_hrc_delete.
TYPES:
BEGIN OF t_mark,
mark TYPE c,
END OF t_mark,
BEGIN OF t_str_reservationx.
INCLUDE STRUCTURE zptb00_hreservat.
INCLUDE TYPE t_mark.
TYPES:
END OF t_str_reservationx.
DATA:
l_dis TYPE disvariant,
l_str_layout TYPE slis_layout_alv,
l_str_exit_by_user TYPE slis_exit_by_user,
l_tab_reservationx TYPE STANDARD TABLE OF t_str_reservationx,
l_str_reservationx TYPE t_str_reservationx,
l_tab_reservation TYPE STANDARD TABLE OF zptb00_hreservat,
l_count TYPE i.
FIELD-SYMBOLS:
<l_str_reservation> TYPE zptb00_hreservat,
<l_str_reservationx> TYPE t_str_reservationx.
SELECT * FROM zptb00_hreservat INTO TABLE l_tab_reservation.
LOOP AT l_tab_reservation ASSIGNING <l_str_reservation>.
MOVE-CORRESPONDING <l_str_reservation> TO l_str_reservationx.
APPEND l_str_reservationx TO l_tab_reservationx.
ENDLOOP.
l_str_layout-colwidth_optimize = 'X'.
l_str_layout-window_titlebar = TEXT-003.
l_str_layout-box_fieldname = 'MARK'.
l_dis-report = sy-repid.
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_callback_program = l_dis-report
i_callback_pf_status_set = 'CB_ALV_PF_SET_STATUS'
i_callback_user_command = 'CB_ALV_USER_COMMAND'
i_structure_name = 'ZPTB00_HRESERVAT'
is_layout = l_str_layout
i_default = 'X'
i_save = 'A'
is_variant = l_dis
IMPORTING
es_exit_caused_by_user = l_str_exit_by_user
TABLES
t_outtab = l_tab_reservationx
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
CASE 'X'.
WHEN l_str_exit_by_user-exit.
LEAVE PROGRAM.
WHEN l_str_exit_by_user-back OR l_str_exit_by_user-cancel.
RETURN.
ENDCASE.
l_count = 0.
LOOP AT l_tab_reservationx ASSIGNING <l_str_reservationx>.
IF <l_str_reservationx>-mark = 'X'.
DELETE FROM zptb00_hreservat WHERE id = <l_str_reservationx>-id.
ENDIF.
ENDLOOP.
MESSAGE s002(zptb00_messages_alv) WITH l_count.
ENDFORM. " zptb00_hrc_delete
FORM zptb00_hrc_show.
DATA: l_dis TYPE disvariant,
l_rda_table TYPE REF TO data,
l_str_layout TYPE slis_layout_alv,
l_tab_reservation TYPE STANDARD TABLE OF zptb00_hreservat.
SELECT * FROM zptb00_hreservat INTO TABLE l_tab_reservation.
l_str_layout-colwidth_optimize = 'X'.
l_str_layout-window_titlebar = TEXT-004.
l_dis-report = sy-repid.
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_structure_name = 'zptb00_hreservat'
is_layout = l_str_layout
i_save = 'A'
is_variant = l_dis
TABLES
t_outtab = l_tab_reservation
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDFORM.
FORM cb_alv_user_command USING r_ucomm LIKE sy-ucomm
rs_selfield TYPE slis_selfield.
IF r_ucomm = 'EXECUTE'.
rs_selfield-exit = 'X'.
ENDIF.
ENDFORM.
FORM cb_alv_pf_status USING rt_extab TYPE slis_t_extab.
SET PF-STATUS 'STANDARD_FULLSCREEN' EXCLUDING rt_extab.
ENDFORM.
我不知道我是否正確,但是在您設置的“ REUSE_ALV_GRID_DISPLAY ”函數中的“ zptb00_hrc_delete ”表單中:
I_CALLBACK_PF_STATUS_SET = 'CB_ALV_PF_SET_STATUS'
但是,“ CB_ALV_PF_SET_STATUS ”表單不存在。 我認為您拼錯了表單的名稱,因為有一個名為“ CB_ALV_PF_STATUS ”的表單似乎很合適:
FORM cb_alv_pf_status USING rt_extab TYPE slis_t_extab.
SET pf-status 'STANDARD_FULLSCREEN' EXCLUDING rt_extab.
ENDFORM.
讓我們嘗試在“ REUSE_ALV_GRID_DISPLAY ”調用中更改它,如下所示:
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
I_CALLBACK_PROGRAM = l_dis-report
I_CALLBACK_PF_STATUS_SET = 'CB_ALV_PF_STATUS' " ---> 'CB_ALV_PF_SET_STATUS' replaced by 'CB_ALV_PF_STATUS'
I_CALLBACK_USER_COMMAND = 'CB_ALV_USER_COMMAND'
I_STRUCTURE_NAME = 'ZPTB00_HRESERVAT'
IS_LAYOUT = l_str_layout
I_DEFAULT = 'X'
I_SAVE = 'A'
IS_VARIANT = l_dis
IMPORTING
ES_EXIT_CAUSED_BY_USER = l_str_exit_by_user
TABLES
T_OUTTAB = l_tab_reservationx
EXCEPTIONS
PROGRAM_ERROR = 1
OTHERS = 2.
我假設 ' STANDARD_FULLSCREEN ' GUI 狀態存在。 請檢查一下。
另一個觀察結果是,在“ zptb00_hrc_show ”形式中,您在函數“ REUSE_ALV_GRID_DISPLAY ”的“ i_structure_name ”參數中使用小寫字母,但它應該是大寫字母。
代替:
i_structure_name = 'zptb00_hreservat'
它應該是:
i_structure_name = 'ZPTB00_HRESERVAT'
希望能幫助到你
在您的第 161 行中,您設置了:
SET pf-status 'STANDARD_FULLSCREEN' EXCLUDING rt_extab.
nmiranda 假設存在“STANDARD_FULLSCREEN”GUI 狀態。 我認為它不存在。
你能用 SE38 打開你的報告,顯示代碼廣告嗎?雙擊STANDARD_FULLSCREEN
。 如果您收到警告,表明該狀態不存在,則您確定了問題。
如果狀態存在:您是否定義了刪除按鈕?
如果沒有 -> 定義一個。 如果您不知道該怎么做,請發表評論。 我會檢查是否可以制作屏幕截圖(抱歉,實際上我沒有可用的 SAP)。
如果你定義了一個按鈕,請檢查我調試表rt_extab
的內容。 如果它包含刪除操作的用戶命令,則該按鈕將被抑制。 (我在你的代碼中沒有發現任何東西,可以肯定的是,它填滿了表格)。
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.