使用 awk 格式化列中的日期

Question

我只是想解決這個問題。 我正在運行下面的代碼

 awk -F, 'NR>1{gsub(/\:/,"",$4);gsub(/\-/,"",$4);gsub(/\.0/,"",$4);gsub(/\ /,",",$4);NF--}{$1=$1}1' OFS=, sample

$cat 樣本

 1,0,null,2014-11-24 08:15:18.0,1
 1,0,null,2014-11-24 08:15:16.0,1

輸出是

1,0,null,2014-11-24 08:15:18.0,1
1,0,null,20141124,081516

我的預期輸出：

1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

誰能幫我上面的代碼？

Answer 1

你可能只需要

awk -F, '{gsub(/[-:]/,"",$4);sub(/ /,OFS,$4);sub(/\.0$/,"",$4)}1' OFS=, sample

Answer 2

#!/usr/bin/awk -f
$1 {
  gsub(/(\.0|[-:])/, "")
  gsub(/ /, ",")
  print
}

Answer 3

而不是使用gsub ，你最好使用split 。

awk '
BEGIN { FS = OFS = "," }
{
    split ($4, flds, /[- :.]/);
    $4 = flds[1] flds[2] flds[3] FS flds[4] flds[5] flds[6]
 }1' sample
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

• 我們將BEGIN塊中的輸入和輸出字段分隔符設置為, 。
• 使用split ，我們在- , : , 上split第四個字段. 並將空間放入數組。
• 然后我們通過連接數組元素重新構造第四個字段。
• 1最后會做默認的awk動作，即print 。

Answer 4

$ awk 'BEGIN{FS=OFS=","} {gsub(/[-:]|\.0/,"",$4); sub(/ /,OFS,$4)} 1' file
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

或者：

$ awk 'BEGIN{FS="[ ,]";OFS=","} {gsub(/-/,"",$4); gsub(/:|\.0/,"",$5)} 1' file
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1