Format date in a column using awk

Question

I just want to fix this problem. I am running the code below

 awk -F, 'NR>1{gsub(/\:/,"",$4);gsub(/\-/,"",$4);gsub(/\.0/,"",$4);gsub(/\ /,",",$4);NF--}{$1=$1}1' OFS=, sample

$cat sample

 1,0,null,2014-11-24 08:15:18.0,1
 1,0,null,2014-11-24 08:15:16.0,1

The output is

1,0,null,2014-11-24 08:15:18.0,1
1,0,null,20141124,081516

My expected output:

1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

Anyone who could help me with my code above?

Answer 1

你可能只需要

awk -F, '{gsub(/[-:]/,"",$4);sub(/ /,OFS,$4);sub(/\.0$/,"",$4)}1' OFS=, sample

Answer 2

#!/usr/bin/awk -f
$1 {
  gsub(/(\.0|[-:])/, "")
  gsub(/ /, ",")
  print
}

Answer 3

Instead of using gsub , you are better off using split .

awk '
BEGIN { FS = OFS = "," }
{
    split ($4, flds, /[- :.]/);
    $4 = flds[1] flds[2] flds[3] FS flds[4] flds[5] flds[6]
 }1' sample
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

• We set the input and output field separator in the BEGIN block to , .
• Using split , we break the forth field on - , : , . and space in to an array.
• We then re-construct the forth field by concatenating the array elements.
• 1 at the end will do default awk action, that is print .

Answer 4

$ awk 'BEGIN{FS=OFS=","} {gsub(/[-:]|\.0/,"",$4); sub(/ /,OFS,$4)} 1' file
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1

or:

$ awk 'BEGIN{FS="[ ,]";OFS=","} {gsub(/-/,"",$4); gsub(/:|\.0/,"",$5)} 1' file
1,0,null,20141124,081518,1
1,0,null,20141124,081516,1