如何從跨平台的Haskell代碼播放音頻文件

Question

我正在編寫一個在Linux，Windows和OS X上運行的Haskell命令行應用程序。我現在必須從中播放音頻文件（ .wav ， .ogg和.mp3 ）。 我將如何實現一個功能

playAudioFile :: FilePath -> IO ()

甚至更好

playAudio :: ByteString -> IO ()

只是適用於所有系統？

（我很高興調用常見的命令行工具，也不介意將它們捆綁為Windows發行版。）

Answer 1

這是我提出的代碼，使用SDL-1.2：

module PlaySound (withSound, playSound) where

import Control.Monad
import System.IO
import System.Directory
import Data.Foldable
import Control.Exception
import qualified Data.ByteString.Lazy as B
import Foreign.ForeignPtr

import Graphics.UI.SDL as SDL
import Graphics.UI.SDL.Mixer as Mix

withSound :: IO a -> IO a
withSound = bracket_ init cleanup
  where
    init = do
        SDL.init [SDL.InitAudio]
        getError >>= traverse_ putStrLn
        ok <- Mix.tryOpenAudio Mix.defaultFrequency Mix.AudioS16LSB 2  4096
        unless ok $
            putStrLn "Failed to open SDL audio device"

    cleanup = do
        Mix.closeAudio
        SDL.quit

playSound :: B.ByteString -> IO ()
playSound content = do
        dir <- getTemporaryDirectory
        (tmp, h) <- openTempFile dir "sdl-input"
        B.hPutStr h content
        hClose h

        mus <- Mix.loadMUS tmp
        Mix.playMusic mus 1
        wait

        -- This would double-free the Music, as it is also freed via a
        -- finalizer
        --Mix.freeMusic mus
        finalizeForeignPtr mus
        removeFile tmp

wait :: IO ()
wait = do
    SDL.delay 50
    stillPlaying <- Mix.playingMusic
    when stillPlaying wait

該程序最終工作正常，但是

• 在Windows下編譯SDL綁定很棘手。 我按照這個很好的解釋如何做到這一點
• SDL-1.2的SDL綁定似乎沒有維護， 甚至不能用GHC-7.8或更新版本編譯 。 起初我沒有注意到，因為我的發行版（Debian）修補了這些問題，但這意味着我的用戶不能輕易地再次cabal install依賴項。
• SDL-2有綁定，但SDL_mixer沒有綁定，我在這里需要（我相信）。

所以我很樂意閱讀更好的答案。