[英]Speedup long running loop in ABAP
在分析 SAP 導出腳本 (SAP R/3, 4.06b) 中的性能問題時,我發現以下代碼在測試系統中運行了大約 10 分鍾。 在生產中可能會快一點,但我無法在那里進行測試。
LOOP AT ZMARD.
LOOP AT ZCOMB.
IF ZCOMB-MATNR = ZMARD-MATNR.
IF ZCOMB-LGORT = ZMARD-LGORT.
IF ZCOMB-IND = ' '.
IF ZCOMB-PLUMI = '+'.
ZMARD-LABST = ZMARD-LABST + ZCOMB-MNG01.
ELSEIF ZCOMB-PLUMI = '-'.
ZMARD-LABST = ZMARD-LABST - ZCOMB-MNG01.
ENDIF. "PLUMI
ENDIF. "IND
ENDIF. "LGORT
ENDIF. "MATNR
ENDLOOP.
IF ZMARD-LABST < 0.
ZMARD-LABST = 0.
ENDIF.
WRITE ZMARD-LABST DECIMALS 0 TO ZMARD-ZLABST.
MODIFY ZMARD.
ENDLOOP.
對於如何優化此循環/將它們組合成一個循環,您有什么建議嗎?
你好肯定有一些可能性。
第一:您可以使用“where external looped struct-field” = “inner loop table field”來調節內循環。
第二:您可以使用哈希表。 但是這些對於讀取表來說更重要。
我認為你應該過濾內循環。 此外,我會將這些表定義為 SORTED 表(WITH NON-SORTED KEY),至少是帶有鍵 MATNR、LGORT 和 IND 的“ZCOMB”。
我還會使用 sy-tabix 變量來保持行的位置,然后像這樣使用它:
MODIFY ZMARD INDEX lv_tabix.
或者我可以使用字段符號。 是你的選擇。
代碼如下所示:
DATA lv_index type sy-tabix.
LOOP AT ZMARD.
lv_index = sy-tabix.
LOOP AT ZCOMB WHERE MATNR = ZMARD-MATNR AND LGORT = ZMARD-LGORT AND IND = ' '.
IF ZCOMB-PLUMI = '+'.
ZMARD-LABST = ZMARD-LABST + ZCOMB-MNG01.
ELSEIF ZCOMB-PLUMI = '-'.
ZMARD-LABST = ZMARD-LABST - ZCOMB-MNG01.
ENDIF. "PLUMI
ENDLOOP.
IF ZMARD-LABST < 0.
ZMARD-LABST = 0.
ENDIF.
WRITE ZMARD-LABST DECIMALS 0 TO ZMARD-ZLABST.
MODIFY ZMARD INDEX lv_index.
ENDLOOP.
最后,在我看來,另一種方法是遍歷“ZCOMB”並使用 COLLECT 對數據求和,並使用這些總和修改“ZMARD”,使用 BINARY SEARCH 讀取表。
在我看來,這可以提高性能,因為您只會循環一張表。
希望能幫助到你。
這是需要將兩個表相交的經典案例。 您示例中的代碼是最糟糕的方法之一,可以顯着改進。 這是一篇關於此的有趣文章。
這是為您的示例實現的。
假設: 1. ZMARD 對於 MATNR LGORT 組合沒有重復條目; 2. ZMARD的順序對報告不重要;
DATA: IX_MARD TYPE I,
IX_COMB TYPE I.
DEFINE READ_NEXT.
ADD 1 TO IX_&1.
READ TABLE Z&1 INDEX IX_&1.
IF SY-SUBRC NE 0.
IX_&1 = -1.
ENDIF.
END-OF-DEFINITION.
" It would be better if these sorts were done
" in the SELECT of the data
SORT ZMARD BY MATNR LGORT.
SORT ZCOMB BY MATNR LGORT.
IX_MARD = IX_COMB = 0.
READ_NEXT: MARD, COMB.
WHILE IX_MARD GT 0 AND IX_COMB GT 0.
IF ZMARD-MATNR EQ ZCOMB-MATNR AND
ZMARD-LGORT EQ ZCOMB-LGORT.
" Match between MARD and COMB
IF ZCOMB-IND = ' '.
IF ZCOMB-PLUMI = '+'.
ZMARD-LABST = ZMARD-LABST + ZCOMB-MNG01.
ELSEIF ZCOMB-PLUMI = '-'.
ZMARD-LABST = ZMARD-LABST - ZCOMB-MNG01.
ENDIF. "PLUMI
ENDIF. "IND
READ_NEXT: COMB.
ELSEIF ZMARD-MATNR LT ZCOMB-MATNR OR
( ZMARD-MATNR EQ ZCOMB-MATNR AND
ZMARD-LGORT LT ZCOMB-LGORT
).
" MARD behind COMB
IF ZMARD-LABST < 0.
ZMARD-LABST = 0.
ENDIF.
WRITE ZMARD-LABST DECIMALS 0 TO ZMARD-ZLABST.
MODIFY ZMARD INDEX IX_MARD.
READ_NEXT MARD.
ELSE.
" MARD ahead of COMB
READ_NEXT COMB.
ENDIF. " Match on material and storage location
ENDWHILE.
WHILE IX_MARD GT 0.
IF ZMARD-LABST < 0.
ZMARD-LABST = 0.
ENDIF.
WRITE ZMARD-LABST DECIMALS 0 TO ZMARD-ZLABST.
MODIFY ZMARD INDEX IX_MARD.
READ_NEXT MARD.
ENDWHILE.
請注意,我剛剛在這里編輯了這段代碼,所以我預計它會有一些語法錯誤和錯誤。
似乎這段代碼想要更新ZMARD-LABST
中所有條目的ZMARD-LABST
LABST。 在表循環中循環表似乎真的很慢。 如果您在 MATNR 上對 ZMARD 進行排序,那么您可以在 2 個不同的循環中執行此操作。 就像是
DATA lv_tabix type sy-tabix.
FIELD-SYMBOLS <MARD> like ZMARD. "I dont know the type of ZMARD
SORT ZCOMB BY MATNR.
LOOP AT ZCOMB.
IF ZCOMB-IND NE ' '.
CONTINUE.
ENDIF.
IF <MARD>-MATNR NE ZCOMB-MATNR OR <MARD>-LGORT NE ZCOMB-LGORT.
"This could be a binary read, because of sorting we only do a read per material
READ TABLE MARD ASSIGNING <MARD> WITH KEY MATNR = ZCOMB-MATNR LGORT = ZCOMB-LGORT.
IF SY-SUBRC NE 0.
CONTINUE.
ENDIF.
ENDIF.
IF ZCOMB-PLUMI = '+'.
ADD ZCOMB-MNG01 TO <MARD>-LABST.
ELSEIF ZCOMB-PLUMI = '-'.
SUBTRACT ZCOMB-MNG01 FROM <MARD>-LABST.
ENDIF.
ENDLOOP.
LOOP AT ZMARD.
lv_index = sy-tabix.
IF ZMARD-LABST < 0.
ZMARD-LABST = 0.
ENDIF.
WRITE ZMARD-LABST DECIMALS 0 TO ZMARD-ZLABST.
MODIFY ZMARD INDEX lv_tabix.
ENDLOOP.
請注意,MARD 有 3 個鍵:MATNR、BUKRS 和 LGORT。 我希望您的 LGORT 值不會與 WERKS 交叉,或者 ZCOMB 有一個您可以使用的 WERKS 字段。
如果你不關心執行順序,你可以這樣做(未經測試):
SORT ZMARD BY MATNR LGORT.
SORT ZCOMB BY MATNR LGORT.
LOOP AT ZMARD ASSIGNING <ZMARD>.
READ TABLE ZCOMB WITH KEY
MATNR = <ZMARD>-MATNR
LGORT = <ZMARD>-LGORT
TRANSPORTING NO FIELDS.
IF sy-subrc = 0.
lv_index = sy-tabix.
ELSE.
CONTINUE.
ENDIF.
LOOP AT ZCOMB ASSIGNING <ZCOMB> FROM lv_index.
IF <ZCOMB>-MATNR <> <ZMARD>-MATNR OR <ZCOMB>-LGORT <> <ZMARD>-LGORT.
EXIT.
ENDIF.
IF <ZCOMB>-IND = ' '.
IF <ZCOMB>-PLUMI = '+'.
<ZMARD>-LABST = <ZMARD>-LABST + <ZCOMB>-MNG01.
ELSEIF ZCOMB-PLUMI = '-'.
<ZMARD>-LABST = <ZMARD>-LABST - <ZCOMB>-MNG01.
ENDIF.
ENDIF.
ENDLOOP. " ZCOMB loop
端環。 " ZMARD 循環
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.