如何使用變量作為sub的參數？

Question

我想將變量用作我的子對象的參數之一，因此我可以應用DRY: Don't Repeat Yourself在代碼中DRY: Don't Repeat Yourself 。 我真的不確定該怎么說，因為標題似乎與我的真實問題無關。

基本上我有想要轉換為sub的代碼，所以我可以多次調用它

Dim counter_1 As Integer = 0
Dim counter_2 As Integer = 0
Dim num_blink As Integer

Private Sub Tmr_Recall_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_01.Tick
    num_blink = ((CInt(My.Settings.num_blink) - 1) * 2)
    Service_Num = "01"
    Console.WriteLine(counter_1)
    Console.WriteLine(num_blink)
    If Lbl_Temp_01.Text = "1" Then
        If counter_1 <= num_blink Then
            For Each Ctrl_Panel As Panel In Me.Pnl_Service.Controls.OfType(Of Panel)()
                If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                    For Each Ctrl_Lbl In Ctrl_Panel.Controls
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                    Next
                End If
            Next Ctrl_Panel
            counter_1 += 1
        Else
            Lbl_Temp_01.Text = "0"
            counter_1 = 0
        End If
    Else
        For Each Ctrl_Panel As Panel In Me.Pnl_Service.Controls.OfType(Of Panel)()
            If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                For Each Ctrl_Lbl In Ctrl_Panel.Controls
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                Next
            End If
        Next Ctrl_Panel
    End If
End Sub

Private Sub Tmr_Recall_02_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_02.Tick
    num_blink = ((CInt(My.Settings.num_blink) - 1) * 2)
    Service_Num = "02"
    Console.WriteLine(counter_2)
    Console.WriteLine(num_blink)
    If Lbl_Temp_02.Text = "1" Then
        If counter_2 <= num_blink Then
            For Each Ctrl_Panel As Panel In Me.Pnl_Service.Controls.OfType(Of Panel)()
                If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                    For Each Ctrl_Lbl In Ctrl_Panel.Controls
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                    Next
                End If
            Next Ctrl_Panel
            counter_2 += 1
        Else
            Lbl_Temp_02.Text = "0"
            counter_2 = 0
        End If
    Else
        For Each Ctrl_Panel As Panel In Me.Pnl_Service.Controls.OfType(Of Panel)()
            If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                For Each Ctrl_Lbl In Ctrl_Panel.Controls
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                Next
            End If
        Next Ctrl_Panel
    End If
End Sub

在該代碼中，您可以看到我重復了很大一部分代碼，因為我想將其應用到我的2個計時器中（實際上，我正在使用6個計時器，它可能甚至更多）

這就是為什么我發現將其轉換為sub更為實用，並且它就在這里。

Sub recall_Service_num(Service_Num As String, Lbl_Temp As Label, counter As Integer)
    num_blink = ((CInt(My.Settings.num_blink) - 1) * 2)
    Console.WriteLine(counter)
    Console.WriteLine(num_blink)
    If Lbl_Temp.Text = "1" Then
        If counter <= num_blink Then
            For Each Ctrl_Panel As Panel In frmQueuing.Pnl_Service.Controls.OfType(Of Panel)()
                If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                    For Each Ctrl_Lbl In Ctrl_Panel.Controls
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                        If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                            If CType(Ctrl_Lbl, Label).Visible = False Then
                                CType(Ctrl_Lbl, Label).Visible = True
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                            End If
                            If CType(Ctrl_Lbl, Label).ForeColor = Color.Red Then
                                CType(Ctrl_Lbl, Label).Visible = False
                            End If
                            If CType(Ctrl_Lbl, Label).Visible = True Then
                                CType(Ctrl_Lbl, Label).ForeColor = Color.Red
                            End If
                        End If
                    Next
                End If
            Next Ctrl_Panel
            counter += 1
        Else
            Lbl_Temp.Text = "0"
            counter = 0
        End If
    Else
        For Each Ctrl_Panel As Panel In frmQueuing.Pnl_Service.Controls.OfType(Of Panel)()
            If TypeOf Ctrl_Panel Is Panel And Ctrl_Panel.Name = "Pnl_Service_" & Service_Num Then
                For Each Ctrl_Lbl In Ctrl_Panel.Controls
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Current_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                    If TypeOf Ctrl_Lbl Is Label And Ctrl_Lbl.Name = "Lbl_Service_Window_" & Service_Num Then
                        CType(Ctrl_Lbl, Label).ForeColor = Color.Black
                        CType(Ctrl_Lbl, Label).Visible = True
                    End If
                Next
            End If
        Next Ctrl_Panel
    End If
End Sub

所以現在我可以這樣使用

Dim counter_1 As Integer = 0
Dim counter_2 As Integer = 0
Dim counter_3 As Integer = 0
Dim counter_4 As Integer = 0

Private Sub Tmr_Recall_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_01.Tick
    recall_Service_num("01", Lbl_Temp_01, counter_1)
End Sub

Private Sub Tmr_Recall_02_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_02.Tick
    recall_Service_num("02", Lbl_Temp_02, counter_2)
End Sub

Private Sub Tmr_Recall_03_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_03.Tick
    recall_Service_num("03", Lbl_Temp_03, counter_3)
End Sub

Private Sub Tmr_Recall_04_Tick(sender As Object, e As EventArgs) Handles Tmr_Recall_04.Tick
    recall_Service_num("04", Lbl_Temp_04, counter_4)
End Sub

我的問題是， counter_1 ， counter_2等在recall_Service_num("01", Lbl_Temp_01, counter_1)似乎不起作用？ 關於如何在我的子目錄中將變量添加為參數之一的任何想法？

Answer 1

計數器參數通過ByVal傳遞（即變量的副本）。

您需要在ByRef中傳遞它。

Sub recall_Service_num(Service_Num As String, Lbl_Temp As Label, ByRef counter As Integer)

Answer 2

除了按照編碼器|的建議傳遞計數器ByRef之外，還可以使用Controls.Find（）獲得對所需Labels的引用：

Sub recall_Service_num(ByVal Service_Num As String, ByVal Lbl_Temp As Label, ByRef counter As Integer)
    num_blink = ((CInt(My.Settings.num_blink) - 1) * 2)
    Dim lblServiceCurrent As Label = frmQueuing.Controls.Find("Lbl_Service_Current_" & Service_Num, True).FirstOrDefault
    Dim lblServiceWindow As Label = frmQueuing.Controls.Find("Lbl_Service_Window_" & Service_Num, True).FirstOrDefault

    If Lbl_Temp.Text = "1" Then
        If counter <= num_blink Then
            If Not IsNothing(lblServiceCurrent) Then
                If lblServiceCurrent.Visible = False Then
                    lblServiceCurrent.Visible = True
                    lblServiceCurrent.ForeColor = Color.Black
                End If
                If lblServiceCurrent.ForeColor = Color.Red Then
                    lblServiceCurrent.Visible = False
                End If
                If lblServiceCurrent.Visible = True Then
                    lblServiceCurrent.ForeColor = Color.Red
                End If
            End If

            If Not IsNothing(lblServiceWindow) Then
                If lblServiceWindow.Visible = False Then
                    lblServiceWindow.Visible = True
                    lblServiceWindow.ForeColor = Color.Black
                End If
                If lblServiceWindow.ForeColor = Color.Red Then
                    lblServiceWindow.Visible = False
                End If
                If lblServiceWindow.Visible = True Then
                    lblServiceWindow.ForeColor = Color.Red
                End If
            End If

            counter += 1
        Else
            Lbl_Temp.Text = "0"
            counter = 0
        End If
    Else
        If Not IsNothing(lblServiceCurrent) Then
            lblServiceCurrent.ForeColor = Color.Black
            lblServiceCurrent.Visible = True
        End If

        If Not IsNothing(lblServiceWindow) Then
            lblServiceWindow.ForeColor = Color.Black
            lblServiceWindow.Visible = True
        End If
    End If
End Sub