如何使用SAS對下一行的值求和？

Question

我想在我的數據集中創建一個列，該列計算當前行和另一個字段的下一行的總和。 數據中有幾個組，如果下一行是當前組的一部分，我只想取下一行的總和。 如果一行是該組的最后一條記錄，我想用一個空值填充。

我指的是在當前觀察中讀取下一個觀察的值 ，但仍無法弄清楚如何獲得所需的解決方案。

例如：

data have;
   input Group ID Salary;
   cards;
10 1 1
10 2 2
10 3 2
10 4 1
11 1 2
11 2 2
11 3 1
11 4 1

;
run;

我想在這里獲得的結果是這樣的：

data want;
   input Group ID Salary Sum;
   cards;
10 1 1 3
10 2 2 4
10 3 2 3
10 4 1 .
11 1 2 4
11 2 2 3
11 3 1 2
11 4 1 .

;
run;

Answer 1

與Tom的答案類似，但使用的是'look-ahead'合並（不帶by語句，並且firstobs=2 ）：

data want ;
  merge have
        have (firstobs=2 
              keep=Group Salary 
              rename=(Group=NextGroup Salary=NextSalary)) ;

  if Group = NextGroup then sum = sum(Salary,NextSalary) ;

  drop Next: ;
run ;

Answer 2

使用BY組處理和第二個SET語句跳過第一個觀察值。

data want ;
  set have end=eof;
  by group ;
  if not eof then set have (keep=Salary rename=(Salary=Sum) firstobs=2);
  if last.group then Sum=.;
  else sum=sum(sum,salary);
run;

Answer 3

我發現了使用proc expand產生我所需的解決方案：

proc sort data = have;
    by Group ID;
run;

proc expand data=have out=want method=none;
 by Group;
 convert Salary = Next_Sal / transformout=(lead 1);
run;

data want(keep=Group ID Salary Sum);
    set want;
    Sum = Salary + Next_Sal;
run;