使用SUMIFS在Excel中提取年初至今的銷售數據

Question

我正在尋找一種為A，B，C列中包含以下內容的電子表格提取YTD數據的方法。

我希望它能夠拉出當年的當前月份並從中比較C列中的YTD銷售額。

我已經使用= SUM（IF（YEAR（A：A）= 2016，C：C，0））來獲取整年的數據，但只想要jan-列出的每一年的當前月份。

YTD Sales Through May 2008
2009
2010
2011
2012
2013
2014
2015
2016

Jan-03  17  $86,625
Feb-03  17  $107,900
Mar-03  21  $103,400
Apr-03  17  $112,050
May-03  20  $75,145
Jun-03  26  $198,800
Jul-03  14  $80,695
Aug-03  19  $50,940
Sep-03  26  $152,380
Oct-03  23  $109,380
Nov-03  19  $113,875
Dec-03  21  $149,275
Jan-04  30  $113,110
Feb-04  17  $109,493
Mar-04  15  $69,690
Apr-04  25  $123,145
May-04  24  $136,685
Jun-04  30  $148,495
Jul-04  21  $138,990
Aug-04  29  $131,005
Sep-04  38  $165,790
Oct-04  43  $173,190
Nov-04  41  $253,915
Dec-04  39  $217,650

Answer 1

您將使用此公式並將Year更改為所需的值：

=SUMPRODUCT((MONTH($A$1:$A$24)<=MONTH(TODAY()))*(YEAR($A$1:$A$24)=2016)*$C$1:$C$24)

如果您想用一個公式得出年初至今的所有年份，則可以：

=SUMPRODUCT((MONTH($A$1:$A$24)<=MONTH(TODAY()))*(YEAR($A$1:$A$24)={2008,2009,2010,2011,2012,2013,2014,2015,2016})*$C$1:$C$24)

為了使公式更加動態，使其隨數據的大小增長和收縮，請使用此公式；

=SUMPRODUCT((MONTH($A$2:INDEX(A:A,MATCH(1E+99,A:A)))<=MONTH(TODAY()))*(YEAR($A$2:INDEX(A:A,MATCH(1E+99,A:A)))={2004,2005})*$C$2:INDEX(C:C,MATCH(1E+99,A:A)))

確保引用$A$2和$C$2引用數據的第一個單元格而不是標題行。

在數組公式的計算是指數的情況下，我們需要將引用限制為僅數據集大小。 所有INDEX(A:A,MATCH(1E+99,A:A))可以完成此操作。 它將自動用數字A設置最后一行，並將其設置為數據集的最后一行。

因此，隨着數據集的增長或收縮，我們將不會進行任何不必要的迭代。

將{2004,2005}更改為任意年份。