將png圖形文件從Stata寫入Excel

Question

我想在Stata中創建圖形，並將基礎圖形數據（而不是生成它們的原始數據）導出到Excel，與圖形文件一起導出。 我想我堅持使用putexcel的putexcel官方代碼文檔（ http://www.stata.com/manuals14/pputexcel.pdf ），但我不斷收到以下錯誤消息：

picture: expression must be enclosed in ()

當我將相關的代碼行括在括號中時，我得到了錯誤

unknown function picture()

有什么建議或暗示嗎？ 請參閱下面的可立即運行的代碼示例。

sysuse auto, clear
* ------ place for some data manipulations (snip) -----------

tempfile data
save `data'

* plotting
graph bar price foreign
graph export "test.png", replace

* Export plot data (works only w/o by-option in graph command)
serset use
export excel "graphdata.xlsx", sheet("test") firstrow(variables) sheetreplace
putexcel H20 = picture(test.png) using "graphdata.xlsx", sheet("test") modify
serset clear

* re-use original data and plot next graph
use `data', clear

*...

Answer 1

這樣做你想要的：

sysuse auto
export excel using "myresults.xlsx", replace sheet("Data")
graph bar price foreign
graph export "test.png", replace
putexcel set "myresults.xlsx", sheet("Graph") modify
putexcel A1 = picture(test.png)

Answer 2

好吧，由於Stata工作人員的暗示，問題解決了。 對於記錄，這是一個問題，應該使用哪個版本的Stata的putexcel （我沒有使用最新版本 - 抱歉讓你煩惱我的自制問題）。 現在我要使用putexcel版本2.1.1,12aug2016，下面的代碼完美地完成了它的目的（你可以找到你的putexcel版本與which putexcel ）：

sysuse auto, clear
* ------ place for some data manipulations (snip) -----------

tempfile data
save `data'

* plotting
graph bar price foreign
graph export "test.png", replace

* Export plot data (works only w/o by-option in graph command)
serset use
export excel "graphdata.xlsx", sheet("test") firstrow(variables) sheetreplace
putexcel set "graphdata.xlsx", sheet("test") modify
putexcel H20 = picture(test.png)
serset clear

* re-use original data and plot next graph
use `data', clear

*...